"House of Dream of Moon" by The IF Whispers Team

The story headline is "An Interactive Collaboration"

After printing the banner text, say "Type 'about' for more information."

Part 0 - Shared definitions

Use American dialect, the serial comma, and full-length room descriptions.

The maximum score is 100.

Use memory economy.

Include Locksmith by Emily Short.

Include Basic Screen Effects by Emily Short.

The carrying capacity of the player is 5.

A closet is a kind of container.  It is openable, closed and scenery.

A window is a kind of thing.  A window is usually scenery.  A window can be open or closed.  A window is usually closed.  A window can be openable or unopenable.  A window is usually openable.
Instead of looking out a window (called the shiny glass): try examining the shiny glass.

A fluid container is a kind of container.  It can be empty or full.  A fluid container is usually empty.

Liquid is a kind of value.  The liquids are water, and syrup.  A fluid container has a liquid.

After examining a fluid container:
  [say "[description of the noun][paragraph break]";]
  if the noun is empty,
    say "You catch just a hint of [the liquid of the noun] at the bottom.";
  otherwise
    say "[The noun] contains [liquid of the noun]."

Before printing the name of a fluid container (called the target) while not drinking:
  if the target is empty begin;
    say "empty ";
  otherwise;
    do nothing;
  end if.

[After printing the name of a full fluid container (called the target) while not examining:
    say ", which contains [liquid of the target]"]
[LS NOTE:  This rule ended up looking too silly too often.]
Instead of inserting something into a fluid container:
  say "[The second noun] has too narrow a mouth to accept anything but liquids."

Understand "drink from [fluid container]" as drinking.

Instead of drinking a fluid container:
  if the noun is empty begin;
    say "There is no more [liquid of the noun] within." instead;
  otherwise;
    change the noun to empty;
    say "You quaff [the liquid of the noun], leaving [the noun] empty.";
  end if.

Understand the command "fill" as something new.

Understand "pour [something] in/into/on/onto [something]" as pouring it into.  Understand "empty [something] into [something]" as pouring it into.  Understand "fill [something] with/from [something]" as pouring it into (with nouns reversed).

Pouring it into is an action applying to two things. 

Check pouring it into: 
    if the noun is not a fluid container, say "You can't pour [the noun]." instead; 
    if the second noun is not a fluid container, say "You can't pour liquids into [the second noun]." instead; 
    if the noun is the second noun, say "You can hardly pour [the noun] into itself." instead; 
    if the liquid of the noun is not the liquid of the second noun 
    begin; 
        if the second noun is empty, change the liquid of the second noun to the liquid of the noun; 
        otherwise say "Mixing [the liquid of the noun] with [the liquid of the second noun] would give unsavory results." instead; 
    end if; 
    if the noun is empty, say "No more [liquid of the noun] remains in [the noun]." instead; 
    if the second noun is full, say "[The second noun] cannot contain any more than it already holds." instead. 

Carry out pouring it into: 
   now the second noun is full;
   now the noun is empty.

Report pouring it into: 
    say "[The noun] is now empty; [the second noun] contains [liquid of the second noun]." 

A liquid source is a kind of fluid container.  A liquid source is always full.  A liquid source is usually scenery.

Does the player mean pouring a liquid source into a fluid container:  it is very likely.

Carry out pouring a liquid source into:
   now the second noun is full;
   rule succeeds

[ override the fluid container rules for naming ]
After printing the name of a liquid source (called the target) while not examining:
   rule succeeds

Before printing the name of a liquid source (called the target) while not drinking:
  rule succeeds

After pouring a liquid source into a fluid container:
   say "You fill [the second noun] up with [liquid of the noun] from [the noun].";
   change the noun to full.

Instead of pouring a fluid container into a liquid source:
   If the noun is empty, say "[The noun] is already empty." instead;
   say "You dump out [the noun] into [the second noun].";
   change the noun to empty

Looking out is an action applying to one thing.  Understand "look out [something]" as looking out.  Report looking out: say "You can't look out that."

Lying down is an action applying to nothing.  Report lying down: say "You lie down on the hard surface for a bit, then get up."

Understand "lie down" as lying down.

Understand "on/in/inside" or "on top of" as "[within]".

Understand "lie down [within] [something]" as entering.

Understand "lie [within] [something]" as entering.

Understand "lock [something]" as locking keylessly.

Understand "unlock [something]" as unlocking keylessly.

Emptying is an action applying to one thing. Understand "empty [something]" or "empty out [something]" or "empty [something] out" as emptying. Report emptying: say "You will have to do that manually."

Emptying it into is an action applying to two things. Understand "empty [something] in/into/on/onto [something]" as emptying it into. Report emptying it into: say "You will have to do that manually."

Digging is an action applying to nothing. Understand "dig" as digging. Report digging: say "You dig at the ground with your hands, to no avail."

Untangling is an action applying to nothing. Understand "untangle" or "untangle myself/me" as untangling.  Report untangling: say "You don't seem to be tangled up."

Understand the command "free" or "writhe" as "untangle".

Holding breath is an action applying to nothing. Understand "hold breath" or "hold my breath" as holding breath. Report holding breath: say "You breath in. Fwmmmp!"

Exhaling is an action applying to nothing. Understand "exhale" or "release breath" or "release my breath" or "breathe out" or "stop holding breath" or "start breathing" or "breathe" or "take breath" as exhaling. Report exhaling: say "You breathe out. Hahhhhh."

A person can be either unbreathing or breathing. A person is normally breathing.

A room can be either air filled or airless. A room is normally air filled.

After going anywhere when the player is unbreathing:  if the location is air filled, try exhaling.

Instead of holding breath: now the player is unbreathing; say "You inhale mightily and begin holding your breath." Instead of holding breath when player is unbreathing, say "You already are holding your breath."

Instead of exhaling: now the player is breathing; continue the action.

Every turn when the player is breathing and the location is airless: say "Ack! There's no air! You can't breathe, and suffocate horribly!"; end the game in death.

[Omitting this rule doesn't make sense, but I don't like this kind of puzzle.]
[LS NOTE:  I put this back in, but such that it's impossible to fail to solve the 'puzzle' of holding your breath at the right time, by hooking it into maga's new rules in part 4 ('try exhaling').]
Every turn (this is the timed unbreathing rule):
If the player is unbreathing begin;
	if the player has been unbreathing for more than zero turns begin;
		if the player has been unbreathing for at most six turns, say "You courageously continue holding your breath.";
	end if;
	if the player has been unbreathing for exactly seven turns, say "Holding your breath is becoming difficult!";
	if the player has been unbreathing for exactly eight turns, say "You can't hold your breath much longer!";
	if the player has been unbreathing for nine turns begin; say "You are unable to hold your breath anymore! You exhale and gasp!"; try exhaling;  end if;
end if.

[The no-dying rule:]
[Every turn when the player has been unbreathing for more than zero turns, say "You courageously continue holding your breath."]

Before asking something about something while player is unbreathing: now player is breathing; say "You exhale loudly.[paragraph break]".

Understand the command "read" as something new. Understand "read [something]" or "consult [something]" or "read in/from [something]" as reading. Reading is an action applying to one thing, requiring light. Instead of reading something (called Foo): try examining Foo.

A thing can be examined or unexamined.  A thing is usually unexamined.  

Carry out examining something: 
     now the noun is examined.

[This bit courtesy Ricardo Dague from Whispers 2]
A person has a table-name called the replies. The replies of a person is usually Table of Non Replies.

Table of Non Replies
  topic	reply
  --	"** error: replying to null topic **"

Instead of asking a person about a topic listed in the replies of the noun:
  say "[reply entry][paragraph break]".

Instead of answering a person that a topic listed in the replies of the noun:  say "[reply entry][paragraph break]";

Does the player mean taking scenery:  it is unlikely.

Rule for deciding whether all includes scenery:  it does not.

The scene-manager is a thing.  It has a number called authnum.  The authnum of the scene-manager is 1.

When Whisper 2 begins:  Now the authnum of the scene-manager is 2.

When Whisper 3 begins:  Now the authnum of the scene-manager is 3.

When Whisper 4 begins:  Now the authnum of the scene-manager is 4.

When Whisper 5 begins:  Now the authnum of the scene-manager is 5.

When Whisper 6 begins:  Now the authnum of the scene-manager is 6.

When Whisper 7 begins:  Now the authnum of the scene-manager is 7.

When Whisper 8 begins:  Now the authnum of the scene-manager is 8.

When Whisper 9 begins:  Now the authnum of the scene-manager is 9.

When Whisper 10 begins:  Now the authnum of the scene-manager is 10.

Finding out about the game is an action out of world.  Understand "about" or "help" as finding out about the game.  Carry out finding out about the game:
	say "'House of Dream of Moon' is the third IF Whispers game, written consecutively by ten people who only got to see the part before theirs.  It follows in the glorious footsteps of 'The Corn Identity' and 'An Escape to Remember', but shares nothing but the format and a few authors with those games.  Tom Blawgus was the moderator of this Whispers incarnation, and wrote the first section.  To see who wrote any given section, type 'author' while playing that section."

Seeing the author is an action out of world. Understand "author" as seeing the author. Carry out seeing the author: 
	if there is an author corresponding to a num of the authnum of the scene-manager in the Table of Whispers begin;
		choose row with a num of the authnum of the scene-manager in the Table of Whispers;
		say "Scene [num entry], '[title entry]', was written by [author entry].";
	otherwise;
		say "Hmm, there seems to be no author set at this point. Well, maybe this part was written by monkeys.";
	end if.

Table of Whispers
Num	Author	Title
1	"Tom Blawgus"	"Going Exploring"
2	"Carl Muckenhoupt"	"Introducing the Great Masters"
3	"Ricardo Dague"	"End of the World"
4	"Sam Kabo Ashwell"	"The Great Lunar Conspiracy"
5	"Jacqueline A. Lott"	"Night of the Wombat"
6	"Mark J. Musante"	"Entering the Unknown"
7	"Lucian Smith"	"Imposing Some Structure"
8	"Admiral Jota"	"Mechanisms and More"
9	"Taleslinger"	"The cute and the Deadly"
10	"N. B. Horvath"	"Puff of Smoke"



Chapter 0 - Useful playtesting verbs - Not for release

Skipping ahead is an action applying to nothing.  Understand "skip ahead" as skipping ahead.  The last carry out skipping ahead rule: say "Since we should always be in a scene, there's no reason to see this text, unless someone forgot to define an override for their scene."

Unrandomizing is an action out of world. Understand "unrandomize" as unrandomizing. Carry out unrandomizing: say "Bing, the world is now deterministic. Or as deterministic as it gets, anyway."; seed the random-number generator with 31337.


Test wh0 with "test wh1 / test wh2 / test wh3 / test wh4 / test wh5 / test wh6 / test wh7 / test wh8/  test wh9 / test endgame"


Part 1 - Going Exploring by Tom Blawgus

Whisper 1 is a scene.

Chapter 0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 1:
say "Skipping Scene 1";
move backpack to player;
move sheet to player;
move water_bottle to player;
move flashlight to player;
change entered the woods to 1;
move the player to the Edge of the Woods;
Rule succeeds.

Test wh1 with "get up / open closet / get all / e / x leslie  / e / open closet / get all / w / tell leslie about sheet / s / tell leslie about spare bedroom / e / x detangler / pull trigger / open fridge / get bottle / g / close fridge / e / e / close door / e";

Chapter 1 - everything else

Entered the woods is a number variable.  Entered the woods is 0.

Whisper 1 ends when Entered the woods is 1.

Whisper 1 begins when play begins. 
When Whisper 1 begins:
	say "Your very first night is over in your new house.  It still seems surreal that you are now the proud owner of this place.  It doesn't quite feel like home yet since you haven't been able to get your furniture.  However, you can't get the rental truck until tomorrow.  Maybe today would be a good idea to explore those woods behind your house.  It'll be a good way to kill time until you can get properly moved in tomorrow.".

The house key is carried by the player.  It unlocks the front door.  The description of the house key is "Your house key.  Without it, you wouldn't feel safe going anywhere."

The Master Bedroom is a room.  "All that's unpacked in the room is your mattress[if sheet is not handled] with a sheet thrown over the top of it[end if].  Your dresser is still in storage.  Windows look out to the north and west, and the closet lies to the south.  The hallway is to the east."
Instead of going south in the Master Bedroom, say "The closet's much too small to fit in."

The mattress is a supporter.  It is enterable and scenery.  It is in the Master Bedroom.  The description of the mattress is "At least you were able to haul this here on the top of your car.  It would have been quite uncomfortable to sleep on the floor."  Understand "bed" as the mattress.

The sheet is scenery on the mattress.  The description of the sheet is "You are thankful that you had the foresight to have a cover if needed, though the nights have been warm lately.  You have no idea why you forgot the pillow."

After putting the sheet on the mattress: now the sheet is not scenery; continue the action.

After dropping the sheet when the player is on the mattress: now the sheet is scenery; continue the action.

A procedural rule for taking the sheet when the sheet is scenery: ignore the can't take scenery rule; ignore the can't take what's fixed in place rule; now the sheet is not scenery; now the sheet is not fixed in place.

The player is on the mattress.

The master closet is a closet.  It is in the Master Bedroom.  Understand "closet" as the master closet.  The printed name of the master closet is "closet".  The description of the master closet is "Where you will hang your clothes, once you're able to retrieve them.  [if open]Inside the closet you can see: [a list of things in the master closet][otherwise]It's currently closed[end if]."
Instead of entering the master closet, try going south.
Instead of opening the master closet when the player is on the mattress, say "You're not Mr. Fantastic.  You'll need to get up to reach the closet."

The backpack is a player's holdall.  It is wearable.  It is in the master closet.  The description of the backpack is "Your trusty backpack.  You've never found a way to completely fill it, thus it is your constant companion on your journey."  Understand "pack" as the backpack.

The north master window is a window.  It is in the Master Bedroom.  The printed name of the north master window is "north window".  The description of the north master window is "You look out the window and see the neighbor's fence."

The west master window is a window.  It is in the Master Bedroom.  The printed name of the west master window is "west window".  The description of the west master window is "You look out the window and gaze upon your front lawn and the street beyond it."

The master bedroom door is a door and scenery.  It is east of the Master Bedroom and west of the Hallway.  It is open.  The description of the master bedroom door is "If you didn't live alone, this would be more useful."

The Hallway is a room.  "Peeling paint greets you as you gaze down the hallway.  Once you get moved in and get your car back, a trip to the paint store is on your list of things to do.  The threadbare carpet leads you south, or you can step into your bedroom to the west.  The bathroom lies to the north, and there's a spare bedroom to the east."

The Bathroom is a room.  "All the usual fixtures are here.  Unfortunately the water isn't turned on yet, so you can't use any of them.  It's on your ever-growing list of things to do after getting your stuff."

The bathroom door is a door and scenery.  It is north of the Hallway and south of the Bathroom.  It is open.  The description of the bathroom door is "It looks a little worse for wear, like water vapor has been seeping into the paint."

The toilet is an openable closed container.  It is scenery.  It is in the Bathroom.  "A bit worse for wear, but it appears to be functional."
Instead of opening the toilet, say "Yup.  There's no water in there."

The bathtub is an open container.  It is scenery and in the Bathroom.  Understand "bath" as the bathtub.  The description of the bathtub is "Nope... no water in there either."

The sink is an open container.  It is scenery and in the Bathroom.  The description of the sink is "As hard as you look, you can find no evidence of water."

The Spare Bedroom is a room.  "This is room is about as empty as your bedroom.  There are windows looking north and east, and there's a closet to the south."
Instead of going south in the Spare Bedroom, say "The closet's much too small to fit in."

The spare closet is a closet.  It is in the Spare Bedroom.  Understand "closet" as the spare closet.  The printed name of the spare closet is "closet".  The description of the spare closet is "More storage space for your stuff once you get it out of storage.  [if open]Inside the closet you can see: [a list of things in the spare closet][otherwise]It's currently closed[end if]."

Instead of entering the spare closet, try going south.

Instead of opening the spare closet for the first time: say "Opening the closet reveals a flashlight.  The previous owners must have forgotten it when they moved out."; Now the spare closet is open.

A flashlight is a switched off device.  Understand "torch" and "light" as the flashlight.  It is in the spare closet.  It is switched off.  The description of the flashlight is "A durable flashlight found in the spare room closet."  Carry out switching on the flashlight: now the flashlight is lit.  Carry out switching off the flashlight: now the flashlight is unlit.

The north spare window is a window.  It is in the Spare Bedroom.  The printed name of the north spare window is "north window".  The description of the north spare window is "You look out the window and see the neighbor's fence."

The east spare window is a window.  It is in the Spare Bedroom.  The printed name of the east spare window is "east window".  The description of the east spare window is "You look out the window and gaze into your back yard and the woods beyond.  You can also see the windows of the Sun Room and see a bit of the room itself."

The spare room door is a door and scenery.  It is west of the Spare Bedroom and east of the Hallway.  It is open.  The description of the spare room door is "Looks like someone kicked in this door once.  There's a hole in it."

The Living Room is a room.  It is south of the Hallway.  "Hardwood floors greet you and your steps echo as you walk around the room.  There is a window in the west wall looking out into the front yard.  The front door is to the west, and the kitchen lies to the east."

The living room window is a window.  It is in the Living Room.  The printed name of the living room window is "window".  The description of the living room window is "You can see your front yard and driveway."

The front door is west of the Living Room and east of the Front of House.  It is a door and scenery.  The front door is locked.  Understand "door" as the front door.  The description of the front door is "A plain front door that allows you access to the front yard.  It is currently [if door is locked]locked[otherwise]unlocked[end if]."

The Front of House is a room.  "A neatly manicured lawn greets you and runs all the way to the sidewalk.  Your driveway is to the south and you can step back inside to the east."
Instead of going nowhere from the Front of House, say "Today's not the day to explore the neighborhood.  Today's the day to explore the woods."

A front lawn is scenery.  The printed name of the front lawn is "lawn".  The description of the front lawn is "It is lush and green."

Check locking keylessly:
  if the noun is not lockable, say "[The noun] is not something you can lock." instead;
  if the noun is locked, say "[The noun] is already locked." instead;
  if the player carries the house key and the player is in the Front of House, try locking the noun with the house key instead;
  if the player is in the Front of House, say "You can't lock the door from this side without the key." instead.

Carry out locking keylessly:
  now the noun is locked.

Report locking keylessly:
  say "You turn the lock in the doorknob to lock [the noun]."

Check unlocking keylessly:
  if the noun is not lockable, say "[The noun] is not something you can unlock." instead;
  if the noun is unlocked, say "[The noun] is already unlocked." instead;
  if the player carries the house key and the player is in the Front of House, try unlocking the noun with the house key instead;
  if the player is in the Front of House, say "You can't unlock the door from this side without the key." instead.

Carry out unlocking keylessly:
  now the noun is unlocked.

Report unlocking keylessly:
  say "You turn the lock in the doorknob to unlock [the noun]."
 
The Driveway is a room.  It is south of the Front of House.  "The concrete is cracked but is still servicable to park your car.  The garage itself lies to the east, but there's no handle on this side of the garage door.  Add a trip to the hardware store to your list of things to do."
Instead of going east in the Driveway, say "There's no way into the garage from here."
Instead of going nowhere from the Driveway, say "Today's not the day to explore the neighborhood.  Today's the day to explore the woods."

The car is an enterable thing.  It is fixed in place.  It is in the Driveway.  The description of the car is "Your trusty car that can get you places, except into the woods."  Instead of entering the car, say "Today's not the day to explore the neighborhood.  Today's the day to explore the woods."

The Kitchen is a room.  It is east of the Living Room.  "A small kitchen, perfect for one.  Cupboards line the north wall, and there's a refigerator in the corner next to the oven.  Oh, and there's also a kitchen sink.  You can walk west to the living room, or east down some steps into the sun room."

Instead of going somewhere from the Kitchen when the refrigerator is open, say "You shouldn't exit the kitchen and leave the refrigerator open."

Instead of going down in the Kitchen, try going east.

Some cupboards are an openable closed container.  They are scenery.  They are in the Kitchen.  Understand "cupboard" as the cupboards.  The description of the cupboards is "They line the north wall of the kitchen."  Instead of opening the cupboards: say "You open them one by one and find nothing in them.  Your dishes are still in storage."

The kitchen sink is an open container.  It is scenery.  It is in the Kitchen.  The description of the kitchen sink is "Now you've seen everything... except water."

The oven is an openable closed container.  It is scenery.  Understand "stove" as the oven.  It is in the Kitchen.  The description of the oven is "An electric oven with four burners on top."  Instead of opening the oven: say "You open it and gaze in, but you find nothing."

The refrigerator is an openable closed container.  It is scenery.  Understand "fridge" as the refrigerator.  It is in the Kitchen.

A water_bottle is a fluid container.  It is full.  It is in the refrigerator.  The liquid of the water_bottle is water.  The printed name of the water_bottle is "water bottle".  Understand "water bottle" as the water_bottle.  Understand "water" as the water_bottle.  Understand "bottle" as the water_bottle.  The description of the water_bottle is "Just the thing to have along in case you get thirsty."  Instead of emptying water_bottle into, say "We wouldn't want to get [the second noun] wet, now would we?".  The inventory listing of the water_bottle is "water bottle[if full], which contains [liquid of the water_bottle][otherwise] (empty)[end if][if the tadpole is part of the water_bottle], and a tadpole[end if]"

Instead of emptying the full water_bottle:
   say "You pour out the bottle.";
   now the water_bottle is empty

Instead of examining the water_bottle when the tadpole is part of the water_bottle:
   say "[The water_bottle] is full of water, and there's a tadpole swimming around in it!";

Does the player mean pouring the stream into the water_bottle:  It is likely.

Instead of drinking the water_bottle when the tadpole is part of the water_bottle:
         say "You drink all the water from the bottle, including the yummy little tadpole inside!";
            change the water_bottle to empty;
            remove the tadpole from play;

The Sun_Room is a room.  It is east of the Kitchen.  The printed name of the Sun_Room is "Sun Room".  Understand "Sun Room" as the sun_room.  The description of the Sun_Room is "A vast open room at the back of the house with windows on all sides.  A door looking something like one you'd see on a barn leads outdoors, while the garage is to the southwest.  The kitchen is up some steps to the west."
Instead of going up in the Sun_Room, try going west.

The sun_room_windows is a window.  It is in the Sun_Room.  The printed name of the sun_room_windows is "windows".  Understand "window" as the sun_room_windows.  The description of the sun_room_windows is "Everywhere you look out you can see your back yard and the lawn.  The forest begins where the lawn ends.  You can also see the spare room window, but you can't see in."

The barn door is east of the Sun_Room and west of the Back Yard.  It is a door and scenery.  Understand "door" as barn door.  The description of the barn door is "A giant door more than twice the size of any normal door allows access to the back yard beyond."

The Garage is a room.  It is southwest of the Sun_Room.  "Obviously this garage was built many years ago because there's no way the modern car would fit in it.  As a result, it becomes a convenient place to store your stuff when you get it out of storage.  The garage door lies to the east, but it's locked shut and the realtor forgot to give you the key to the padlock.  Another chore for you after moving in."

The Back Yard is a room.  "A large carpet of green stretches all the way to the back of the property where the woods start.  The house is back to the west, and you can enter the woods to the east."

The back lawn is scenery.  It is in the Back Yard.  The printed name of the back lawn is "lawn".  The description of the back lawn is "The grass is everywhere, from the house to the edge of the forest."

Instead of going east in the Back Yard:
  if the front door is not locked or the barn door is open begin;
     say "Are you going to leave your house open when you explore?";
  otherwise;
    if Entered the woods is 1 begin;
      continue the action;
    otherwise;
      if the player encloses the backpack and the player encloses the water_bottle and the player encloses the sheet and the player encloses the flashlight begin;
        say "With anticipation, trepidation and excitement, you enter the woods.";
        change entered the woods to 1;
        move player to The Edge of the Woods;
      otherwise;
        say "You don't feel quite ready to enter the woods yet.";
      end if;
    end if;
  end if.

The Edge of the Woods is a room.  It is east of the Back Yard.  "Looking back through the trees, you can still make out your house.  Looking forward, you see the vast wilderness surrounds you that is just begging to be explored.  A path meaders through the trees leading east."


Part 2 - Introducing the Great Masters by Carl Muckenhoupt

Whisper 2 is a scene. Whisper 2 begins when Whisper 1 ends.
Whisper 2 ends when the player is in Blast Site for the first time.

Chapter 0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 2:
say "Skipping Scene 2";
remove the lesser mantid from play;
remove the dead_flies from play;
move the mantid head to Edge of the Woods;
now the Great Master is trusting;
move the player to Blast Site;
Rule succeeds.

test wh2 with "test wh2a  / test wh2b "

test wh2a with "ask master about woods / ask master about loyalty / ask master about service / tell leslie about edge of woods / w / w / sw / get flies / tell leslie about flies / ne / i / attach focuser to base / fire detangler";

test wh2b with " w / w / w / s / give flies to mantid / get mantid / n / e  / close door / lock it / e / e  / e / close door / e / give mantid to master / e"

Chapter 2.1 - Spicing up the house a little

In the master closet is a swibble with description "It's just a swibble."  Instead of doing anything other than examining with the swibble:
	say "You can't intefere with a swibble! It would be... well, you just can't."

Some cobwebs are in Garage. Understand "web/webs" and "cobweb" as the cobwebs.  The cobwebs are fixed in place.  The description of the cobwebs is "Sign of the enemy! Vile! Vile!"  Instead of taking, burning, rubbing, touching, or pulling the cobwebs, try attacking the cobwebs.  Instead of attacking the cobwebs:
	remove the cobwebs from play;
	say "You obliterate the unclean thing.  Hopefully you can forget that your beautiful new home ever contained such inappropriate filth."

In the garage are some dead_flies. The printed name of the dead_flies is "dead flies".  Understand "dead" as the dead_flies.  Understand "flies" as the dead_flies.  Understand "dead flies" as the dead_flies.  After taking the dead_flies for the first time, say "Taken. Ick."

In the bathroom is a surveillance camera with description "It's the standard bathroom cam, same as in every other place you've ever lived."  The surveillance camera is fixed in place.  Understand "cam" as the surveillance camera.

Chapter 2.2 - The lesser mantid

A lesser mantid is a neuter animal in the driveway. "A lesser mantid stands here, staring fascinated at the reflection of the sunlight reflected on the pavement by the rear view mirror."  The description is "A beautiful insectoid, related to the Great Masters, but not intelligent, and much smaller.  This one is barely the size of a dog."

Understand "beloved" as the lesser mantid.

The lesser mantid can be trusting or untrusting. The lesser mantid is untrusting.
Instead of showing the dead_flies to the lesser mantid, try giving the dead_flies to the lesser mantid. Instead of giving the dead_flies to the lesser mantid:
	now the lesser mantid is trusting;
	remove dead_flies from play;
	say "You kneel down and hold out the dead flies on your palm. The mantid approaches cautiously, then delicately picks up the flies in its mandibles one by one and crunches them down. It seems less skittish now."

[Animals are not normally takable. This is an exception.]
Instead of taking the lesser mantid:
	if the lesser mantid is trusting begin;
		move the lesser mantid to the player;
		 say "It nestles into your arms and leans against your shoulder, its chitinous spines gently pricking your skin.";
	otherwise;
		 say "It skitters away at your approach.";
	end if;

Table of Mantid Actions
unheld	held
"The lesser mantid uses a foreclaw to clean its large, soulful compopund eyes."	"The lesser mantid gently squeezes your arm in its powerful mandibles."
"The lesser mantid cocks its head."	"The lesser mantid snuggles its head against your shoulder. Its antennae tickle your chin."
"The lesser mantid stridulates plaintively."	"The lesser mantid burbles."
"The lesser mantid shakes itself with a rattling noise."	"You reposition the lesser mantid to hold its weight better."
"The lesser mantid skitters in a circle."	"The lesser mantid writhes."

Every turn when the player has the lesser mantid:
	if a random chance of 1 in 3 succeeds begin;
		choose a random row in the Table of Mantid Actions;
		say "[the held entry][paragraph break]";
	end if.

Every turn when the player can see the lesser mantid:
	if the player does not have the lesser mantid and a random chance of 1 in 3 succeeds begin;
		choose a random row in the Table of Mantid Actions;
		say "[the unheld entry][paragraph break]";
	end if.

The lesser mantid head is a thing with description "Well, you're sure it was justified."

Chapter 2.3 - The Great Master

A Great Master is a neuter person in Edge of the Woods. "A Great Master stands by the path in watchful posture.[if the Edge of the Woods is visited][otherwise] You are awestruck. No one mentioned when you bought the house that you would be graced with such a blessing.

The Great Master acknowldeges you with a wave of its foreclaw, and you hear its voice resonate in your head: GREETINGS, SOFT ONE. ACCESS TO THE WOODS IS RESTRICTED." The description is "Magnificent, benevolent, wise, and at least eight feet tall. To gaze on it is to be honored. Its carapace is brilliant green, its compound eyes are irridescent blue-red. It stands in the Ready Watcher pose, four legs on the ground, its great knifelike foreclaws crossed in front of its thorax."

The great master can be trusting or untrusting. The great master is untrusting.

Table of Great Master Replies
topic	reply	second
"path/woods/thing/terrible/access"	"THE WOODS HIDE A TERRIBLE THING. ACCESS IS PERMITTED ONLY TO THOSE OF ASSURED LOYALTY."	"ACCESS DENIED."
"loyal/loyalty" or "assured/untested loyalty"	"A SERVICE IS REQUIRED. RESTORE THE BELOVED TO US."
"lesser/mantid/beloved/service"	"THE BELOVED HAS STRAYED. BRING IT TO US THAT IT MAY REJOICE IN OUR LOVE ONCE MORE."	"BRING US THE BELOVED."
"love/rejoice/guidance"	"THE SOFT ONES DO NOT TRULY UNDERSTAND LOVE. THIS IS WHY YOU NEED OUR GUIDANCE."
"great/master/masters/itself/himself/herself"	"THE GREAT MASTERS PROVIDE GUIDANCE. THIS ONE IS ASSIGNED TO WATCH OVER THE WOODS, THAT THOSE OF UNTESTED LOYALTY MAY NOT BE EXPOSED TO THE TERRIBLE THING WITHIN."
"house/key"	"WE CONGRATULATE YOU ON ACQUIRING THE NEARBY RESIDENCE. IT IS IN A GOOD NEIGHBORHOOD, NEAR SCHOOLS."
"flashlight"	"IT DOES NOT BELONG TO US."
"water/bottle"	"NO THANK YOU."
"sheet/bedsheet"	"WE DO NOT KNOW WHY YOU PICKED THAT UP EITHER"

Table of Revised Great Master Replies
topic	reply	second
"war"	"THIS SUBJECT IS FORBIDDEN."	"You can't talk about that.  It's forbidden."
"blast/site/blasting/unlife/anti-life"	"YOUR INQUIRY INTO BLAST TECHNOLOGY HAS BEEN LOGGED AND REGISTERED. FURTHER INQUIRY WILL RESULT IN PERSONAL INVESTIGATION."	"And subject yourself to personal investigation? No thanks!"
"path/woods/thing/terrible/access"	"ACCESS GRANTED."
"loyal/loyalty/assured/untested"	"YOU RETURNED THE BELOVED. YOU ARE LOYAL."
"lesser/mantid/beloved/service/head"	"[if the lesser mantid is in Edge of the Woods]THE BELOVED MUST NOT STRAY.[otherwise]IT WILL STRAY NO MORE."
"great/master/masters/itself/himself/herself"	"THIS ONE IS ASSIGNED TO WATCH OVER THE WOODS."
"love/rejoice/guidance"	"LOVE IS SOMETIMES HARSH. WE DO WHAT WE MUST."

The Great Master has a table-name called the replies. The replies of the Great Master is Table of Great Master Replies.

Instead of asking the Great Master about something:
	repeat through the replies of the Great Master begin;
		if the topic understood includes topic entry begin;
			say "[reply entry][paragraph break]";
			if there is a second entry then change the reply entry to the second entry;
			rule succeeds;
		end if;
	end repeat;	
	 say "Why waste a Great Master's time with something irrelevant?"

Instead of giving or showing the lesser mantid to the great master, try silently dropping the lesser mantid. After dropping the lesser mantid in the presence of the Great Master:
	move the lesser mantid to Edge of the Woods;
	change the replies of the Great Master to Table of Revised Great Master Replies;
	execution occurs in five turns from now;
	now the Great Master is trusting;
	say "You place it on the ground in front of the Great Master, who places its foreclaws around its neck protectively. You hear the Great Master's voice in your head: WE THANK YOU FOR THE RETURN OF THE BELOVED. YOU ARE LOYAL, SOFT ONE."
Instead of taking the lesser mantid in the presence of the Great Master, say "The Great Master stops you. Again you hear its words: THE BELOVED MUST NOT STRAY AGAIN."

At the time when execution occurs:
	if the player can see the Great Master, say "The Great Master casually snips off the lesser mantid's head, then picks up and eats its body.";
	remove the lesser mantid from play;
	move the mantid head to Edge of Woods.

Instead of telling the Great Master about something, try asking the Great Master about it. Instead of answering the Great Master that something, try asking the Great Master about it.

Before going east from Edge of the Woods while the Great Master is untrusting, say "The Great Master stops you. You hear its voice in your head: ACCESS DENIED." instead.

Instead of attacking the great master, say "You can barely even articulate the thought."

Chapter 2.4 - Blast Site

Blast Site is east of Edge of the Woods. "There's a perfectly spherical gap in the forest here, thirty feet in diameter, where nothing can grow.  Tall maple and birch trees bend around this bubble of unlife.  Distant blackbirds call."

Before going to Blast Site while the Great Master is trusting for the first time, say "Fallen leaves crunch underfoot as you trundle exploritatively down the sun-dappled path. Fresh air, exercise, the beauty of nature: all is good. Until, quite suddenly, you get an uncanny feeling, like someone stepped on your grave.

You can't put your finger on it at first. Then you notice that the small clearing you've stepped into is perfectly spherical, the trees bending around it and in some cases cut by an invisible field.  And you understand: this is a blast site. Unwholesome relic of the war, a zone of anti-life created by the humans[apostrophe] weapons when they tried to... to...

You choke back tears. How could people have ever been so foolish?"

The trees are scenery in Blast Site with description "On the very edge of the blast radius, you can see older trees that were partly sheared away, and healed over. The newer growth simply bends around the dead zone, as if growing around a wall. Branches hang down to within several inches of the upper boundary."  Understand "tree/birch/maple/woods/forest" as the trees.

Instead of listening when in Blast Site, say "Somewhere, a red-winged blackbird gives a throaty cry in defense of its tree."

Part 3 - End of the World by Ricardo Dague

Whisper 3 is a scene. Whisper 3 begins when Whisper 2 ends. Whisper 3 ends when player is in Lunar Crater for the first time.

Chapter 0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 3:
say "Skipping Scene 3";
now the tadpole is part of the helmet;
now the helmet is in McWiggy;
now the helmet is handled;
now McWiggy is cheerful;
now the shovel counter is 0;
now the player is unbreathing;
say "[paragraph break]You are now holding your breath, since there is no air on the moon.[paragraph break]";
move player to Lunar Crater;
Rule succeeds.

test wh3 with "test wh3a / test wh3b";

test wh3a with "ne / drink bottle / fill bottle / sw / e / e / se / get shovel / yes / tell leslie about shovel / tell leslie about near a huge device / nw / w / w / dig";

test wh3b with "attach power pack to base / fire detangler / pour water into helmet / e / e / se / show helmet to man / z / get hook / throw hook at missile / z / z / hold breath / z / z / z / z / z / z / z  ";

Chapter 3.1 - land rooms

Blastsiteexits is fixed in place thing in Blast Site. It has initial appearance "A path has been hacked through the forest to the east, and you can see something to the northeast."

ByStream is northeast of Blast Site. "Trickling through the forest is a small, clear stream." It has printed name "By a Stream".  Understand "By a stream" as ByStream.

The stream is a liquid source in ByStream with description "You peer into the flowing stream and see something darting among the rocks." Understand "water" or "rocks" as the stream.  The liquid of the stream is water.  Instead of drinking the stream, say "You scoop some water in your hands and slurp it refreshingly."

Hiding_tadpoles are scenery in ByStream.  The printed name of hiding_tadpoles is "tadpoles".  Understand "something" or "darting" or "tadpole" or "tadpoles" as hiding_tadpoles.  The description is "By being patient, you finally see what's darting around in the water--tadpoles!"  Instead of taking the hiding_tadpoles, say "Try as you might, the tadpoles slip through your fingers and under the rocks."

Instead of inserting hiding_tadpoles into the water_bottle, try inserting the water_bottle into the stream.

The tadpole is a thing. It has description "[if tadpole is part of water_bottle]It swims around in the bottle.[otherwise]It flops around in the helmet.[end if]". Instead of taking the tadpole, say "The mouth of the bottle is too narrow to stick your fingers in.". Instead of removing tadpole from something, try taking the tadpole. Instead of taking the tadpole when the tadpole is part of the helmet, say "You try to pick it up, but it slips out of your fingers."

Does the player mean doing something with the tadpole:  It is likely.

Carry out pouring the stream into the water_bottle: now the tadpole is part of the water_bottle.

Instead of inserting something into the stream, say "There's no need to get that wet."

Instead of inserting the helmet into the stream for the first time, say "As soon as the the helmet touches the stream, the tadpoles scatter wildly!  Quickly, you remove the helmet, worried that something from the blast site might contaminate the stream."

Instead of inserting the helmet into the stream, say "No, you don't want to contaminate the stream."

Instead of inserting the water_bottle into the stream, try pouring the stream into the water_bottle.

Instead of pouring the water_bottle into the stream when the tadpole is part of the water_bottle:
	Remove the tadpole from play;
	Now the water_bottle is empty;
	say "You release the tadpole (and the stream water) back into the stream.";	

Path is east of Blast Site. "The forest presses around this narrow throughway leading west to east."

Continuing the Path is east of Path. "The path leads from the west to the southeast, where you sense something oddly sinister."

NearHugeDevice is southeast of Continuing. "The trees have been cut back to make room for this tall device. Looking up at it, you see that it looks like...a phallus? Oh wait, it's a missile. Kind of the same thing, but instead of a little death there's great big death." It has printed name "Near a Huge Device".  Understand "Near a huge device" or "near huge device" as NearHugeDevice.

The missile is scenery in NearHugeDevice. It has description "It's sixty feet tall and gleaming white! An American flag and skull and bones are painted on one side.[if missile is flying] It's flying through the air![end if]". The missile can be either flying or docked. The missile is docked.

The rope is in NearHugeDevice. It has indefinite article "some". It has description "It's a coil of very large-diameter rope, maybe three inches. On one end is a hook[if hook is part of missile], which is stuck to the missile[end if]." Instead of taking the rope, say "The industrial-purpose rope far too heavy for you to lift."

The hook is part of rope. Instead of taking the hook when the hook is part of the missile, say "The hook is stuck securely to the missile!" Instead of removing the hook from something, try taking the hook.  The description is "A wicked-looking hook[if the hook is part of the missile] attached to a rope, coiled on the ground at your feet[otherwise if the hook is part of the rope], neatly coiled with the rope at your feet[otherwise if the player encloses the hook], trailing rope from you to the coil at your feet[otherwise], discarded on the ground and trailing rope to the coil at your feet[end if]."

Instead of taking the hook when the hook is part of the rope:
  Now the hook is in the player;
  say "You pick up the hook, the rope trailing.  You won't be able to get very far this way.";

Instead of going somewhere when the player encloses the hook, say "Not carrying the hook you aren't." 

The shovel counter is a number that varies.

The shovel is in NearHugeDevice. Before taking the shovel when the shovel is not handled: now the shovel counter is the turn count plus 1; say "The man stops you, saying, 'Here now, does that belong to you?'" instead. Instead of saying yes in the presence of McWiggy when the shovel counter is the turn count: move shovel to player;  Now the description of the shovel is "On second thought, you've never seen this shovel before today."; say "He grins. 'Carry on, then!'"  The description is "Hmm, the cracks in the handle look awfully familiar..."

The helmet is a wearable thing. It has description "The standard army helmet is dirty and cracked. A strange green film is on the inside of it.[if tadpole is part of helmet] Plus there's a little tadpole.[end if]". The green_film is part of the helmet.   The printed name of the green_film is "green film".  Understand "green film" as the green_film.  Understand "green" as the green_film.  Understand "film" as the green_film.  The green_film has description "You can't make out what it is." Instead of rubbing the green_film, say "It's strangely gooey."

hint of something yellow is fixed in place in Blast Site.  The initial appearance of the hint of something yellow is "In the fused earth at your feet, you see a hint of something yellow."  The description is "It's vaguely roundish, but you can't tell what it is while it's still buried."  Understand "fused" or "earth" as hint of something yellow.  Instead of taking the hint of something yellow, say "It's too firmly embedded in the fused earth."

Instead of digging while the shovel is carried, say "You dig up nothing useful." Instead of digging in Blast Site, say "You don't dig up anything else." Instead of digging in Blast Site when the helmet is not handled and the shovel is carried: move helmet to player; remove the hint of something yellow from play; say "You dig for a few minutes, turning up an old helmet!"  Instead of digging in Blast Site when the helmet is not handled and the shovel is not carried, say "The fused earth is too hard to dig in with your hands."  Instead of digging in ByStream, say "You'd hate to mess up such a pristine stream."

Instead of pouring water_bottle into helmet when tadpole is part of water_bottle: now tadpole is part of helmet; now the water_bottle is empty; say "The water falls through the cracks in the helmet, but the tadpole is now inside it, flopping around!"

Instead of throwing the hook at something, say "A valiant attempt." Instead of throwing the hook at the missile when the hook is not part of the missile, say "[The McWiggy] gives you such a look and you decide against it." Procedural rule while throwing the hook at something: ignore the carrying requirements rule.

Instead of throwing the hook at the missile when the hook is not part of the missile and McWiggy is upset: now the hook is part of the missile; say "You throw it at the missile! It sticks on! The man yells at you, 'You better not have scratched that!'"

Instead of dropping the hook when the hook is not part of the missile and McWiggy is upset:  now the hook is in the location; say "You flail around some more and end up dropping the hook.  Perhaps if you had a more specific target?";

Chapter 3.2 - McWiggy

The McWiggy is a man in NearHugeDevice. "[if McWiggy is cheerful]A cheerful-looking man in a black two-piece suit and black horn-rimmed glasses stands nearby studying the huge device.[otherwise]An upset-looking man stands here pale and terrified, madly hitting buttons on something like a cellphone.[end if]". He has description "This guy looks like an insurance salesman from the 50s!" He can be either cheerful or upset. He is cheerful. He has printed name "[if McWiggy is cheerful]cheerful[otherwise]upset[end if] man". Understand "cheerful/upset" or "cheerful/upset man" or "man" as McWiggy.

instead of asking McWiggy about something when McWiggy is upset: say "The guy is so upset that he can't hear you."

Instead of asking McWiggy to try saying no: try saying no. Instead of asking McWiggy to try saying yes: try saying yes. Instead of asking McWiggy to try saying sorry: try saying sorry. Instead of answering McWiggy that "yes", try saying yes. Instead of answering McWiggy that "no", try saying no. Instead of answering McWiggy that "sorry", try saying sorry.

Instead of saying yes in the presence of McWiggy, say "He nods happily." Instead of saying no in the presence of McWiggy, say "A blank look forms on his face." Instead of saying sorry in the presence of McWiggy, say "He shrugs." 

Table of McWiggy Replies
topic	reply
"device/missile"	"'It's a fine, fine missile, isn't it? If you saw the blast site to the west, well, that was this fella's little brother's work! Did a beautiful job!'"
"site"	"'You didn't find anything alive there, did you?' His eyes twinkle behind the thick lenses. 'If you did there'd be something seriously wrong! When one of [italic type]our[roman type] missiles land on something, it's completely gone!  In fact, if you [italic type]did[roman type] find anything alive there, I don't know what I'd do!'"
"life"	"'Tut tut! Can't have any more [italic type]life[roman type] than necessary, can we? That's why I'm here.'"
"death"	"'The word [italic type]death[roman type] has a lovely ring, doesn't it?'"
"man/himself"	"'The name is McWiggy.'"

Instead of asking McWiggy about something:
	repeat through Table of McWiggy Replies begin;
		if the topic understood includes topic entry 		begin;
			say "He says, [reply entry][paragraph break]";
			rule succeeds;
		end if;
	end repeat;	
	say "There's a pause, then he says, 'Ah, lovely day, isn't it?'"

Instead of giving something to McWiggy, try showing the noun to the second noun. Instead of showing something to McWiggy, say "'No thank you,' he says, patting his missile. 'This here is all I need to be happy.'"

Instead of showing the helmet to McWiggy, say "He studies it and say, 'I bet you found that in the blast site. The green stuff on the inside are brains!' The man nods smartly. 'That shows the wonderful thoroughness and technological superiority of our missiles!'"

Instead of showing the water_bottle to McWiggy when the tadpole is part of the water_bottle, say "He looks at it a bit nervously.  'Ew, life,' he says.  'At least you didn't find that in the blast site!  That would be tragic.'  He shudders."

Missile firing counter is a number that varies.

Table of Missile Firing
message
"'So sorry,' he says, and pulls out a something that looks like a large cellphone. 'I know what to do now. If [bold type]this[roman type] missile is fired and destroys its target, then we'll know that the last failure was just a fluke, right?'"
"After pressing a few buttons, the man looks up at the missile. 'System check is okay!' he says, then turns to you, 'I suggest you leave. The blast from the rocket engine will kill everyone in this area!'"
"The man says, 'Level B checks clear! Begin firing sequence!' Then he notices you again, 'I thought I told you to go! This is a holy launch and you have no right to be here!'"
"The missile starts making a humming sound, and steam begins blowing out of the base. 'It's about to fire!' he yells at you. 'I guess there's no helping it, if you really need to stay. Bask in the glory with me!'"

Instead of showing the helmet to McWiggy when the tadpole is part of the helmet: move helmet to McWiggy; now McWiggy is upset; say "He stares at the item, his cheer quickly turning into horror. He says, 'What is this?! If you found this helmet in the blast site, and the tadpole was in the helmet, then that means...[bold type]something was left alive![roman type] The missile was a failure? I don't believe it! I refuse to believe it!'
[paragraph break]The man starts running in circles! He's lost his mind!"

Before doing anything when McWiggy has been upset for two turns: 
  if mcwiggy is upset begin; [BUG in I7, 4X60 and earlier]
    now the missile firing counter is one; say "You can't, because suddenly the man runs at you, making you jump backwards! You land on the coil of rope!"; stop the action;
  end if;

Instead of going or exiting when McWiggy is upset: say "You're tangled in the rope! You can't walk anywhere!" Instead of dropping the rope when McWiggy is upset, say "You pull at the rope, but it won't come free!" Instead of untangling when McWiggy is upset, try dropping the rope.

Every turn when missile firing counter >= one:
	choose row missile firing counter in Table of Missile Firing;
	now missile firing counter is missile firing counter plus one;
	if missile firing counter > number of rows in Table of Missile Firing begin;
		now missile firing counter is zero;
		now the missile is flying;
	end if;
	say "[message entry][paragraph break]".

[This works around a bug in Inform 4X60 and earlier:]

Chapter 3.3 - flying

Every turn in NearHugeDevice when missile is flying:
	say "Suddenly the missile roars and flame and smoke shoot out of the base. The heat is becoming unbearable! The man chortles madly. 'Success! Success! Off you go to wreak havoc my boy!'[paragraph break]";
	if hook is not part of missile begin;
		say "As it lifts off you and the man and everything around are consumed in flame!";
		end the game in death;
	otherwise;
		say "It lifts off, with the hook, the rope, and yourself being pulled along! The man yells, 'What do you think you're doing?! You altered the trajectory! It's going straight up!'[paragraph break]As he falls away below, the man is waving his arms, 'Hold your breath! Hold your breath!'";
		move player to Flying Through the Air;
		move missile to Flying Through the Air;
		move rope to Flying Through the Air;
		now the flying counter is one;
	end if.

The flying counter is a number that varies.

Table of Flying
message
"You hang onto the rope for dear life!"
"[if the player is unbreathing]You would scream in terror, but you're trying to hold your breath![otherwise]You scream in terror as you soar along!"
"As the rocket shoots straight up, the air seems to be getting thinner!"
"Hang on! The missile seems to be nearing the end of earth's atmosphere!"
"The missile will enter outer space in just a moment!"
"You fly out into outer space!"
"Terrifyingly, you fly along!"
"Oh no, you're about to hit the moon!"
"With a huge crash, the rocket hits the moon! How you have survived, you don't know.[paragraph break]Though stunned momentarily, you slowly open your eyes and stand up..."

Flying Through the Air is a room. "The missile is roaring towards space, with you in tow! Air and clouds whip by you and the earth below is getting smaller and smaller."

The ground is scenery in Flying Through the Air. It has description "Everything down there is getting smaller and smaller..." Understand "earth" as ground. The clouds are scenery in Flying Through the Air. They have description "They whip buy too fast to see!" Understand "air" as clouds. The outerspace is scenery in Flying Through the Air. It has description "The vast nothingness approaches quickly!" Understand "space" or "outer space" as outerspace.

Every turn while flying counter > 0:
	choose row flying counter in Table of Flying;
	now flying counter is flying counter plus one;
	if flying counter > number of rows in Table of Flying, now flying counter is zero;
	say "[message entry][paragraph break]";
	if flying counter is zero begin;
		now McWiggy is cheerful;
		move player to Lunar Crater;
	end if;
	if flying counter is seven begin;
		move player to Flying Through Space;
		move missile to Flying Through Space;
		move rope to Flying Through Space;
	end if.

Instead of taking the rope when missile is flying, say "It would be more accurate to say that the rope has you."

Flying Through Space is a room. "The missile is shooting toward the moon with you right behind! There's deathly silence here in outer space." Flying Through Space is airless.

The moon is scenery in Flying Through Space. It has description "It is great big and rock-colored!" The earth is scenery in Flying Through Space. It has description "Bye bye, big blue circle!" The stars are scenery in Flying Through Space. They have description "They twinkle silently."

Chapter 3.4 - Lunar Crater

Lunar Crater is a room. "Wow you've landed on the moon! Gray, rocky, dusty, airless landscape stretches all around." Lunar Crater is airless.

Part 4 -  The Great Lunar Conspiracy by Sam Kabo Ashwell

Whisper 4 is a scene. Whisper 4 begins when Whisper 3 ends. Whisper 4 ends when the player is in the Lunar Vinyard for the first time.

Chapter 4.0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 4:
	move the delicious wine to the player;
	now the intoxication of the player is drunk;
	move the fractured arm to the player;
	now the fractured arm is part of the player;
	move the player to the Lunar Vinyard;
	rule succeeds.

test wh4 with "x footprints / dig / open crate / get bottle / tell leslie about bottle / tell leslie about lunar crater / drink wine / get bottle / drink wine / get bottle / n / attach stabilizer to base / fire trigger / jump";

Chapter 4.1 - Crude Pointers and Unwelcome Additions

Instead of throwing the rope at something (called the thingy): try throwing the hook at the thingy.
Instead of tying the rope to something (called the thingy): try throwing the hook at the thingy.
Instead of tying the hook to something (called the thingy): try throwing the hook at the thingy.
Instead of tying the hook to something (called the thingy): try throwing the hook at the thingy.
Instead of putting the hook on something (called the thingy):  try throwing the hook at the thingy.

After examining the shovel:
if the player carries the shovel, say "As you heft the shovel in your hands, you can't help but note its perfect balance and finely-wrought edge. Such a masterful piece of craftsmanship cannot help but fill you with a deep-seated urge to dig randomly for the pure joy of it, wherever you may go."

After examining the tadpole for the first time, say "For a moment, you suspect it might be a larval Overlord, but the metatarsal tubercule is all wrong."

Table of McWiggy Replies (continued)
topic	reply
"Atlantis/Atlanteans"	"'I don't know anything about that. Nope. Nothing whatsoever. Move along, citizen.'"
"Overlords" or "Cosmic Overlords"	"'I am unable to either confirm or deny anything on that subject at this time, and I suggest you confine your questions to the relevant topic, i.e. my enormous weapon.'"
"phallus/enormous weapon"	"'It [italic type]is[roman type] rather impressive, isn't it? I'm told it can be seen from space.'"
"moon"	"'The moon? Hah! With this missile I could pop that overgrown cheeseball out of the sky, if I didn't have far more important things to blow up.'"

Chapter 4.2 - Moonwalk

Instead of exhaling in the Lunar Surface:
	if the player is unbreathing begin;
	say "You remember that the moon's supposed lack of atmosphere is, in fact, yet another scientific hoax. You hadn't realised how deeply the education system had planted lies in your psyche.";
	now the player is breathing;
	now the Lunar Crater is air filled;
	end if;
	continue the action;

Lunar Surface is a region. Lunar Crater is in Lunar Surface. Scenic Overlook is in Lunar Surface.

Lunar Earth is a backdrop. Lunar Earth is in Lunar Surface. The description of Lunar Earth is "Gazing up at the blue-and-white marble that mankind calls home, your heart swells with an inexpressible and profound feeling... of resentment that the Atlanteans imprisoned humanity on such a dingy little orb. No [italic type]wonder[roman type] the females evolved smaller breasts." The printed name of Lunar Earth is "Earth".

After examining Lunar Earth for the first time, say "You note, with a touch of bitterness, the patch of ocean where so-called 'geographers' claim Australia is located. How [italic type]dare[roman type] Google Earth lie to you."

Instead of going nowhere from the Lunar Crater, say "You make an attempt on the crater walls, but they're just too steep. There does seem to be an easier climb to the north, however."

Scenic Overlook is north of Lunar Crater. "You stand on the lip between two overlapping lunar craters; the one into which you crash-landed is dwarfed by the immense, ancient crater before you. Far below you on the crater floor, you can make out patches of green; beyond that, a sprawling silvery mass, many kilometres to the north, that can only be the secret Atlantean lunar base. First, however, you have to find some way of getting down this cliff."
Instead of going nowhere from Scenic Overlook, say "The crater walls are too steep in that direction."

Instead of going north in the Scenic Overlook:
	if the player is sober begin;
	say "The cliffs look too steep to climb easily. Even in lunar gravity, the fall could be fatal. Well... probably. You don't really feel brave enough to find out.";
	otherwise;
		if the player is tipsy begin;
			if the helmet is worn begin;
					say "With a silent invocation to the Cosmic Overlords, you close your eyes and fling yourself off the cliff.[paragraph break]Thanks to lunar gravity, the relaxing effects of pinot noir and your protective headgear, you avoid being splattered like a ripe tomato. And would a true hero be slowed down by a fractured arm? Hardly![paragraph break]";
		move the player to the Lunar Vinyard;
		move the fractured arm to the player;
		now the fractured arm is part of the player;
			otherwise;
			say "You peer over the side. It doesn't really look [italic type]that[roman type] dangerous. Still, it might be better if you were a little more lubricated first, or had some protection.";
			end if;
		otherwise;
		say "With a silent invocation to the Cosmic Overlords, you close your eyes and fling yourself off the cliff.[paragraph break]Thanks to lunar gravity and the relaxing effects of pinot noir, you avoid being splattered like a ripe tomato. And would a true hero be slowed down by a fractured arm? Hardly![paragraph break]";
		move the player to the Lunar Vinyard;
		move the fractured arm to the player;
		now the fractured arm is part of the player;
		end if;
	end if.
	
The cliff is scenery in Scenic Overlook. Understand "rim" as cliff. Understand "crater rim" as cliff. Instead of climbing the cliff:
	if the intoxication of the player is drunk begin;
	say "Sure, it looks safe enough. You swing one leg over the cliff edge, scrape around for a foothold, immediately overbalance and fall for a few hundred metres.[paragraph break]Thanks to lunar gravity, [if helmet is worn]the relaxing effects of pinot noir and your protective headgear[otherwise]and the relaxing effects of pinot noir[end if], you avoid being splattered like a ripe tomato. And would a true hero be slowed down by a fractured arm? Hardly![paragraph break]";
		move the player to the Lunar Vinyard;
		move the fractured arm to the player;
		now the fractured arm is part of the player;
	otherwise;
		if the player is wearing the helmet begin;
		say "Well, the cliff doesn't look very safe, but if the helmet can survive a direct missile strike, it should be able to protect your skull. You swing one leg over the side, scrape around for a foothold, immediately overbalance and fall for a few hundred metres.[paragraph break]Thanks to lunar gravity and your protective headgear, you avoid being splattered like a ripe tomato. And would a true hero be slowed down by a fractured arm? Hardly![paragraph break]";
		move the player to the Lunar Vinyard;
		move the fractured arm to the player;
		now the fractured arm is part of the player;
		otherwise;
		say "The cliff looks really steep, and it's several hundred metres down. You doubt you could climb down safely.";
		end if;
	end if;
	
Instead of jumping in Scenic Overlook, try going north. Instead of going down in Scenic Overlook, try climbing the cliff.

Fractured arm is a thing. The printed name of the fractured arm is "compound ulnar fracture". The description of the fractured arm is "Dammit. There goes your last chance at moon golf."

Lunar Vinyard is a room in Lunar Surface. "Ah, the sun-kissed slopes of Jules Verne Crater, where the grape grows and the wallabies frolic. Presumably. You've yet to see any wallabies, but there are certainly grapevines aplenty."

The grape vines are scenery in Lunar Vinyard. Understand "grapevines" as grape vines. Understand "trellis" as grape vines. Understand "trellises" as grape vines. The description of grapevines is "The delicate trellises are heavy with vines, and provide a pleasant screen to the abyssal darkness of the lunar sky."

Chapter 4.3 - The Almanac

Every Child's Almanac of Lunar Conspiracy is carried by the player. Understand "book" as the Almanac. The description of Almanac is  "Ever since your youth, this book has been your dearest companion. Originally a slender mass-market paperback from Knockoff Press, it now bulges under the weight of your painfully cross-referenced annotations and additions. It largely deals with how the Atlanteans staged the moon landings in order to atrophy America's can-do attitude and defy the Cosmic Overlords, but has valuable information on many related topics."

Table of Ineffable Wisdom
topic	response
"Elvis"	"Elvis, as the world knows, was a renegade Cosmic Overlord who fell to Earth and tampered horribly with both the Cosmic Anthropic Plan and the Atlantean Conspiracy. For this he was blighted with body thetans and sent to the Martian military camps."
"JFK" or "Kennedy"	"JFK, of course, was shot from an orbital defense platform. Well, not so much [italic type]shot[roman type]; a Cosmic Overlord was doing routine maintenance and dropped a rivet."
"wine" or "viticulture"	"Since Australia is entirely mythical, so-called Australian wine has to come from somewhere. Where else but the moon? (There follows a detailed analysis of the viticultural merits of various lunar regions; the author claims most production takes place around the Mare Moscoviense, but your furious marginalia point out that the highlands around the Gauss Crater produce fuller-bodied reds, and, moreover, that the Moscoviensites couldn't recognise a decent vintage with both anal pedipalps.)"
"Atlantis" or "Lemuria" or "Mu" or "Australia"	"A weighty appendix, which constitutes about three-quarters of the book's actual weight, details the histories of such fictional continents as Atlantis, Lemuria, Mu and Australia. Despite their technical non-existence, cultural belief in them sustains their para-existence in the collective subconscious, better known as the moon."
"Atlanteans"	"The book contains a pretty comprehensive summary of Atlantean perfidy, from imperilling the very fabric of the collective subconscious by their treachery against the Cosmic Overlords, to trimming their pubic hairs in your soap dish."
"moon" or "collective subconscious"	"Why does the moon [italic type]coincidentally[roman type] look exactly the same size as the sun? Why did [italic type]all ancient civilisations[roman type] venerate a Moon deity? Why do the Freemasons have [italic type]no lodges in Antarctica[roman type]? If you're not convinced by now, there's clearly no hope for you."
"overlords" or "cosmic overlords"	"Most of your notes on the Cosmic Overlords are still in that Swiss vault. The Atlanteans are doubtless hunting you, and if they found those papers on your laser-scarred corpse - no, it doesn't bear thinking about."
"lunar landings" or "moon landings" or "Apollo mission" or "hoax" or "lunar conspiracy" or "conspiracy" or "atlantean conspiracy"	"At the core of the web of lies the Atlanteans have woven: the supposed moon landings. It is a shadowy business; you have few answers, but many questions. Where did the billions invested in the space program go? What really lurks inside the fridge in the NASA headquarters break room? What fiendish plan are the Atlanteans concocting against the Cosmic Overlords? The answers can only lie in one place: the moon."
"Masons" or "Freemasons" or "Freemasonry" or "Masonry" or "masonic lodges" or "lodges" or "Antarctica"	"Ah, I was just kidding with you. Of [italic type]course[roman type] they have lodges in Antarctica. They're just kind of half-assed lodges with only two beers on tap and second-hand cosmic lunar subconscious projectors that keep breaking down."
"women" or "females" or "Earth females" or "Atlantean females" or "Atlantean women" or "Earth women"	"Two lengthy chapters speculate upon the relative merits of Earth and Atlantean women; the former, it must be confessed, compare poorly. There are many illustrations."
"tadpole" or "larvae" or "tadpoles" or "larva" or "larval Overlord"	"Just to make sure, you skim through the ontogeny section. Yeah, you were right. Not only is the metatarsal tubercule completely different, but larval Overlords are typically the size of small planets. Otherwise they're quite like tadpoles, though."
[Table continuations encouraged.]

Instead of consulting the Almanac about a topic listed in the Table of Ineffable Wisdom:
	say "[response entry][paragraph break]".

Chapter 4.4 - XXX Marks the Spot

A set of suspicious footprints is fixed in place in the Lunar Crater. Understand "tracks" as footprints. "A double line of suspicious footprints leads to the crater's center." The description of footprints is "Leading from the crater lip to the north, the footprints reach [if the crate of wine is in the Lunar Crater]the uncovered wine crate[otherwise]a patch of smooth ground at the crater's centre[end if], then double back."  Instead of entering the footprints, say "You stand at one end of the trail, which fades to the north."

After examining the footprints for the first time, say "The tracks are clearly those of an Atlantean female; the tracks leading into the crater are sunk deeper into the moondust than those going out."

The patch of smooth ground at the crater's center is scenery in Lunar Crater.  Understand "crater center" as the patch of smooth ground.  The description is "Just a patch of smooth ground[if the crate of wine is in the Lunar Crater] in which you discovered a large crate[otherwise], with footprints leading to and from it."  Instead of entering the smooth ground, say "You're already at the patch of smooth ground."

After examining the footprints for the second time, say "You can tell that they were made by an Atlantean by the sixth toe; you can tell that the Atlantean was female because Atlantean women, living in the pure lunar environment, would not have physically degenerated as Earth females have, and would therefore have a [italic type]very[roman type] distinctive gait.[paragraph break]To be honest, just looking at these tracks makes you somewhat aroused."

Instead of digging in the Lunar Crater:
	if the crate of wine is in the Lunar Crater begin;
	say "You grub around in the moondust some more, but to no avail.";
	otherwise;
		if the shovel is carried begin;
		say "You thrust the shovel into the dust and excavate mightily.";
		otherwise;
		say "You dig with your hands. Fortunately the moondust is quite light, although it gets under your fingernails like nobody's business.";
		end if;
		say " It's not long before you've uncovered a large wooden crate.";
		move the crate of wine to the Lunar Crater;
		now the crate of wine is fixed in place;
	end if.

The crate of wine is a openable container. It is closed. The description of the crate of wine is "Ha! You always knew that Australian wines were really lunar in origin, and here is undeniable evidence! "

Instead of taking the crate, say "Even in lunar gravity, the crate is too heavy for a mere Earth-human to lift."

Some wine bottles are inside the crate of wine. Understand "bottle" as the wine bottles. The description of the wine bottles is "Innumerable dark red bottles fill the crate. The Atlanteans may be insane megalomaniacs, but they know how to kick back."
Instead of taking wine bottles:
	if the delicious wine is carried begin;
	say "Atlantean open-container laws are very strict about drinking from more than one bottle at a time. Better not risk it.";
	otherwise;
	say "Glancing around to make sure you are unobserved, you snaffle a bottle of delicious wine.";
	move the delicious wine to the player;
	end if.

The delicious wine is a thing. Understand "Australian wine" as the delicious wine. Understand "bottle" as the delicious wine. Understand "wachawoomagoo slope" as the delicious wine. Understand "red wine" as the delicious wine. Understand "pinot noir" as the delicious wine. The description of the delicious wine is "A bottle of Wachawoomagoo Slope, a perfectly respectable if little-known pinot noir from the Ibn Battuta vinyards."
Does the player mean drinking the crate of wine: it is very unlikely.
Does the player mean taking the crate of wine: it is unlikely.
Instead of drinking the wine bottles:
	try taking the wine bottles;
	try drinking the delicious wines.
Does the player mean drinking the wine bottles: it is unlikely.

Intoxication is a kind of value. The intoxications are sober, tipsy and drunk. The player has an intoxication. The intoxication of the player is usually sober.

After examining the player:
	if the intoxication of the player is tipsy, say "You are somewhat tipsy.";
	if the intoxication of the player is drunk, say "You are horrendously drunk.";

Instead of emptying the delicious wine: try drinking the delicious wine.
Instead of emptying the delicious wine into something: say "That would be a shameful waste."

Instead of opening the delicious wine: say "Wine spoils quickly in the lunar air. Best to wait until it's time to drink it."

Instead of drinking the delicious wine:
	if the intoxication of the player is drunk begin;
	say "No, really, you've had enough. Best to lay this one down for the benefit of your grandchildren, or something.";
	otherwise;
		if the intoxication of the player is sober begin;
		say "Pulling the cork out with your teeth, you knock back the bottle with gusto, then lob the bottle into low orbit.";
		now the intoxication of the player is tipsy;
		otherwise;
		say "Normally you wouldn't drink this much, what with the lunar oxygen saturation and everything... [paragraph break]This time your throw is distinctly wobbly, and the bottle barely makes it over the horizon. Your sense of self-preservation feels somewhat dulled, too.";
		now the intoxication of the player is drunk;
		end if;
	remove the delicious wine from play; 
	end if;

Part 5 -  Night of the Wombat by "Jacqueline A. Lott"

Whisper 5 is a scene. Whisper 5 begins when Whisper 4 ends. Whisper 5 ends when the player is in the Outside Atlantean Base for the first time.

Chapter 5.0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 5:
       remove the fractured arm from play;
       move the player to Outside Atlantean Base;
       remove the wombat from play;
       rule succeeds.

test wh5 with "unrandomize / z / tell leslie about lunar vinyard / climb rock / tell leslie about rock / look up wombat in almanac / attach recharger to base / fire detangler / attack wombat / g / g / g / g"

Chapter 5.1 - Tying up Loose Ends and Other Finishing Touches

Instead of going in the Lunar Vinyard: say "There was seemingly no safe way to enter the crater, and there doesn't seem to be any way back out.  Looks like [if the Little Deceptively Adorable Wombat is in the Lunar Vinyard]there's no running from that aggressive little wombat![line break][otherwise]you're stuck here, pardner."

Understand "prints" as footprints.

The Green is scenery in the Scenic Overlook.  Understand "Eden" as Green.  Understand "Vinyard" as Green.  The description of the Green is "Tiny patches of green dot the otherwise harsh landscape far below.  If only you could find some way to explore that verdant Eden..."  Instead of taking the Green, say "First off, you probably couldn't carry them because the green things are a lot bigger than they look - they're just really far away.  Which brings me to another excellent point - they're [italic type] really far away. [roman type] You'll have to figure out a way to get closer."

The Lunar Base is scenery in the Scenic Overlook.  Understand "sprawling" or "silvery" or "mass" or "Atlantean" as the Lunar Base.  The description of the Lunar Base is "A sprawling silvery mass, yes.  And filled, no doubt, with treachery."  Instead of taking the Lunar Base, say "First off, you can't pick up the sprawling, silvery mass because it's actually a lot bigger than it looks - it's just really far away.  Which brings me to another excellent point - it's [italic type] really far away. [roman type] You'll have to figure out a way to get closer."

The South Crater is scenery in the Scenic Overlook. The printed name of the South Crater is "crater to the south".  Understand "crater to the south" as South Crater.  The description of the South Crater is "You look to the south, toward the crater in which you crash-landed.  In addition to your own tracks, a set of footprints reach [if the crate of wine is in the Lunar Crater]the uncovered wine crate[otherwise]a patch of smooth ground at the crater's centre[end if], then double back."  Instead of taking the North Crater, say "Hahaha - you always loved that old pick up line, 'Is that an enormous lunar crater in your pocket or are you just happy to see me?'  Sadly, you haven't heard that one in years."

The Tracks are scenery in the Scenic Overlook. Understand "footprints" as tracks.  The description of the Tracks is "You look to the south, toward the crater in which you crash-landed.  In addition to your own tracks, a set of footprints reach [if the crate of wine is in the Lunar Crater]the uncovered wine crate[otherwise]a patch of smooth ground at the crater's centre[end if], then double back."  Instead of taking the tracks, say "They're footprints.  They're not really something you can pick up an carry around with you, attractive as they may be."

The North Crater is scenery in the Scenic Overlook.  The printed name of the North Crater is "crater to the north". Understand "crater to the north" as North Crater. The description of the North Crater is "You look to the north, into an almost incomprehensibly large crater.  On the one hand, it doesn't look all [italic type]that [roman type] big, but on the other hand, you realize that it's far more immense than your eye can perceive.  This ain't your first time examining a crater, after all.  Far below, at its center, you can make out patches of green."  Instead of taking the North Crater, say "Hahaha - you always loved that old pick up line, 'Is that an enormous lunar crater in your pocket or are you just happy to see me?'  Sadly, you haven't heard that one in years."

The Big Rough Craggy Moon Rock is an enterable supporter in the Lunar Vinyard.  The Big Rough Craggy Moon Rock is fixed in place.  The printed name of the Big Rough Craggy Moon Rock is "big craggy moon rock".  The description of the Big Craggy Moon Rock is "This is a pretty big moon rock - you could probably sit down on it and take a load off, except that its surface is pretty rough and craggy and it doesn't look all that comfortable."  Instead of taking the Big Rough Craggy Moon Rock, say "Uuuugh!  Nope, you can't lift it[if the Little Deceptively Adorable Wombat is in the Lunar Vinyard], and even if you could, there's no way you could lift it high enough to throw it at that snarling wombat.[otherwise]."

Instead of climbing the big rough craggy moon rock, try entering the big craggy moon rock.

Understand "grapes" as grape vines.  Instead of searching the grape vines: say "You search the grapevines.  That's interesting.  What [italic type]is [roman type] that?  It looks like square poop."; move Cubical Scat to Lunar Vinyard.

Cubical Scat is a thing.  Understand "cube" or "poo" or "poop" or "shit" or "feces" or "crap" or "dung" as Cubical Scat.  The printed name of the Cubical Scat is "square poop".  
      Instead of taking the Scat: say "Ick.  No.  You don't know where that poo has been.  Well, actually, you [italic type]do [roman type] know where it's been, and that's the whole reason you're not going to touch it."  
      Instead of examining the Cubical Scat:
      if the Cubical Scat is examined and the Wombat is not in the Lunar Vinyard begin;
          say "Gosh, you're pretty sure that you read somewhere that wombat scat was cubical, but it's got to be from something else, because wombats don't really exist.";
          end if;
      if the Cubical Scat is examined and the Wombat is in the Lunar Vinyard begin;
          say "Yeah.  The fact that there's actually a wombat standing here is probably a good indication that it really is wombat scat.";
          end if;
      if the Cubical Scat is unexamined and the Wombat is not in the Lunar Vinyard begin;
          say "It's pretty distinctive poop.  You've only ever seen round poop before.  Hm... seems you've read somewhere about square poop... what was it about square poop... oh, yeah.  That's right - wombat scat is supposed to be square.  That's just silliness, though - everyone knows wombats don't really exist.  There must be something else that puts out square poop."; 
          now the Cubical Scat is examined;
          end if;
      if the Cubical Scat is unexamined and the Wombat is in the Lunar Vinyard begin;
          say "It's pretty distinctive poop.  You've only ever seen round poop before.  Hm... seems you've read somewhere about square poop... what was it about square poop... oh, damn.  That's right - wombat scat is square.  Which makes sense, since there's a wombat standing right here in front of you."; 
          now the Cubical Scat is examined;
          end if;



Chapter 5.2 - Wombat Combat!

Every turn when the time since Whisper 5 began is 5 minutes:
	if the Outside Atlantean Base is unvisited and the Little Deceptively Adorable Snarling Wombat is not in the Lunar Vinyard begin;
	move the Little Deceptively Adorable Snarling Wombat to the Lunar Vinyard;
	say "Around the edge of a nearby trellis wanders a heretofore unseen wombat.[paragraph break]Wait.  Wombat?!  Wombats don't exist.  They're like... wallabies.  And kangaroos.  And walaroos.  And Tasmanian devils.  And dingoes who eat babies.  They're all made up, mythical creatures from the fictional continent of Australia...[paragraph break]You rub your eyes in disbelief, but when you look again, the wombat is still there.  Upon seeing you, he stops, cocks his head, then narrows his eyes and wrinkles his hairy snout.  He appears to be... snarling.  It's all a bit of a farce, really - something so little and adorable as a wombat trying to look threatening.[paragraph break]What was it you heard about Wombats, anyway?  They're herbivores... right?[paragraph break]";
	end if;

Every turn when the Little Deceptively Adorable Snarling Wombat has been in the Lunar Vinyard for more than one turn::
    if a random chance of 1 in 3 succeeds begin;
    choose a random row in the Table of Wombat Carnage;
    say "[event entry][line break]";
        if the Health Level of the player is feeling rather crappy begin; change the Health Level of the player to dead; end if;
        if the Health Level of the player is not feeling very good begin; change the Health Level of the player to feeling rather crappy; say "[line break]You're pretty badly hurt.  I sure hope you get your act together soon.  I mean, it's just a little wombat!  An [italic type]herbivore! [roman type] C'mon, hit it[if the Health Level of the Little Deceptively Adorable Snarling Wombat is not feeling fantastic] again![otherwise]![line break]"; end if;
        if the Health Level of the player is honestly not feeling too great begin; change the Health Level of the player to not feeling very good; say "[line break]Um... you might want to consider saving your game now.[line break]"; end if;
        if the Health Level of the player is feeling fantastic begin; change the Health Level of the player to honestly not feeling too great; say "[line break]You might want to keep track of how you're doing by diagnosing yourself.[line break]"; end if;
        if the Health Level of the player is dead begin; end the game saying "You have had your ass handed to you by a tiny wombat."; end if;
end if;

Table of Wombat Carnage
event
"Before you can make a move, the deceptively adorable wombat leaps forward, sharp claws and teeth aimed at your neck! [if the Health Level of the Player is feeling rather crappy]The wombat's teeth find your jugular with surgical precision, and what blood does not coat its gruesome fangs spills out into the reddening ground...[otherwise]You're able to tear away from his vicious teeth just in time..."
"Before you can make a move, the deceptively adorable wombat sprints forward at full speed, knocking you down! [if the Health Level of the Player is feeling rather crappy]As the powerful claws on its feet trample what's left of your bloody frame, you die with the knowledge that wombats, evidently, are meaner than you thought.[otherwise]You're able to scramble back up and turn to face your opponent before the next attack..."
"Before you can make a move, the deceptively adorable wombat lunges forward and head butts you with his big hairy snout! [if the Health Level of the Player is feeling rather crappy]You wobble back, stunned.  Something catches your feet - that big rock, perhaps - and you fall, striking your head on the ground.  Everything goes black...[otherwise]You wobble back, stunned, but are able to regain your senses before the next attack..."
"Before you can make a move, the deceptively adorable wombat sprints forward and pins you against a rock.  [if the Health Level of the Player is feeling rather crappy]The wombat holds your struggling body against the rock so tightly that you can't take in another breath.  Your vision begins to tunnel, then all goes black...[paragraph break]I'm afraid he's asphyxiated you.[otherwise]You are able to wiggle free just before being crushed..."
"Before you can make a move, the deceptively adorable wombat leaps forward and tries to eviscerate you with his mighty digging claws! [if the Health Level of the Player is feeling rather crappy]His claws and teeth expertly find their mark - not only do you have a broken arm, you also have a punctured spleen.  This vicious attack is more than you can endure, I'm afraid...[otherwise]You're able to tear away from his vicious teeth just in time..."
"Before you can make a move, the deceptively adorable wombat leaps forward, feet first, and strikes you in the chest! [if the Health Level of the Player is feeling rather crappy]You are unable to stop yourself, and you fall backward, striking your head against the bolder.  Everything goes black...[otherwise]You're able to tear away from his vicious teeth just in time..."

[Comment: I didn't have time to implement an 'ATTACK WITH' verb.  Feel free to add it if you want to, but I didn't feel it was strictly necessary given our time constraints.]
	
A Health Level is a kind of value. The Health Levels are feeling fantastic, honestly not feeling too great, not feeling very good, feeling rather crappy, dead.
The player has a Health Level.  The Health Level of the player is usually feeling fantastic.
The Little Deceptively Adorable Snarling Wombat has a Health Level.  The Health Level of the Little Deceptively Adorable Snarling Wombat is usually feeling fantastic.

Diagnosing is an action applying to one visible thing. Understand "diagnose [something]" or "diagnose" or "diagno" or "diagno [something]" as diagnosing. 
Instead of diagnosing a person, say "You're really not a medical expert."
Instead of diagnosing an animal, say "You're really not a veterinarian."
Instead of diagnosing something, say "Only living things can be diagnosed."
Instead of diagnosing the player: say "You're [Health Level][if Health Level of the Player is feeling fantastic and Fractured Arm is part of the Player], except for that stupid broken arm.[otherwise]." 


Little Deceptively Adorable Snarling Wombat is a male animal. The printed name of the Little Deceptively Adorable Snarling Wombat is "deceptively adorable wombat". The description of the Little Deceptively Adorable Snarling Wombat is "The sight of the deceptively adorable wombat makes you quake in fear, probably because it's about to kick your ass."
Instead of kissing or touching the Little Deceptively Adorable Snarling Wombat:
    say "Um... it's [italic type]snarling [roman type] at you.  That's not exactly what one expects from an animal seeking out affection."
Instead of attacking the Little Deceptively Adorable Snarling Wombat:
    if a random chance of 3 in 4 succeeds begin;
    choose a random row in the Table of Kicking Ass;
    say "[event entry][line break]";
        if the Health Level of the Little Deceptively Adorable Snarling Wombat is feeling rather crappy begin; change the Health Level of the Little Deceptively Adorable Snarling Wombat to dead; end if;
        if the Health Level of the Little Deceptively Adorable Snarling Wombat is not feeling very good begin; change the Health Level of the Little Deceptively Adorable Snarling Wombat to feeling rather crappy; say "[line break]The wombat is doesn't look quite so agile anymore.  I think you could probably finish the little bugger off.[line break]"; end if;
        if the Health Level of the Little Deceptively Adorable Snarling Wombat is honestly not feeling too great begin; change the Health Level of the Little Deceptively Adorable Snarling Wombat to not feeling very good; say "[line break]The wombat seems to have lost some of the spring in its step.[line break]"; end if;
        if the Health Level of the Little Deceptively Adorable Snarling Wombat is feeling fantastic begin; change the Health Level of the Little Deceptively Adorable Snarling Wombat to honestly not feeling too great; say "[line break]That was a pretty good hit, but it'll take more than that to put the little blighter in line.[line break]"; end if;
        if the Health Level of the Little Deceptively Adorable Snarling Wombat is dead begin; remove wombat from play; say "[line break]That final blow proved to be too much for the wombat - it lies down, rolls over onto its back, its little furry feet wiggle for a few seconds, and then the marsupial goes limp.[paragraph break]Looking down upon its adorable frame, you feel a twinge of remorse.  'It was trying to kill me,' you think to yourself.  'I had no choice but to strike...'  You feel a sudden, odd desire to pet the poor misguided creature.  As you reach out, however, the body starts to shimmer, then fade.  Soon, it is gone altogether."; wait for any key; clear the screen; say "You hear a whisper from behind you.  It says, 'You have proven yourself worthy.'[paragraph break]You turn around to see a shimmering face suspended in the air at eye level.  It is the most beautiful face you have ever seen; being in its presence fills you with a mixture of both fear and awe.  'Are you... one of the Cosmic Overlords?' you stammer.[paragraph break]The face smiles at you benevolently.  'Yes.  The marsupial was... a test.  It is difficult to bring oneself to strike such a fluffy, adorable creature.  Some are so entranced by its fluffiness that they can never bring themselves to attack it - even if it means their own death.  Through your skill and bravery in Wombat Combat, you have proven yourself worthy of our cause.  You will fight the Atlanteans, who in their perfidiousness will use many tricks in an attempt to stay your hand.  Do not fall victim to their beguiling ways.[paragraph break]"; wait for any key; say "'But... I'm hurt.  How can I be of any use?' you whine.[paragraph break]The Cosmic Overlord rolls its eyes, sighs heavily, and says to you, 'Okay, we're not supposed to help you out this much, but just this once we will...'  There is a tingling sensation in your arm... you feel... fantastic.  And your arm seems to have healed.[paragraph break]"; remove fractured arm from play; say "'Gee, thanks, Overlord.  Say, not to sound ungrateful or anything - because I'm certainly very grateful indeed - but... is there anyway you could help me get to the Atlantean Base?'[paragraph break]The Overlord narrows its eyes at you.  'Okay, fine, but really, this is the last time we're helping you."; wait for any key; say "[line break]'Like, really.'"; wait for any key; clear the screen; say "There is a sudden, blinding flash of light, followed by... you're not sure what.  When you regain consciousness, you find yourself in an entirely different place."; wait for any key; clear the screen; move the Player to Outside Atlantean Base; end if;
otherwise; say "I'm afraid you missed.  Don't feel [italic type]too [roman type] bad about that, after all, it's such a tiny target.";
end if;

Understand "pet [something]" as touching.  Understand "pet" as touching.

Table of Kicking Ass
event
"You jump into the air, bend your arm, and BAM!  Come down with an elbow blow to the top of the little wombat's head."
"You take a short running kick at the wombat, and it connects!  The wombat goes flying!"
"You jump to the side just as the wombat comes at you, and turn to jab him in the side as he goes by!"
"You grab the wombat by the ears and fling him into the nearby grapevines!"
"You put everything you have in a solid roundhouse kick, and the wombat shuffles away, yelping!"
"You punch the little guy right in his big hairy snout, and he stumbles backward, addled."


Chapter 5.3 - The Atlantean Base

Moonscape is a backdrop. Moonscape is in Lunar Surface. The description of Moonscape is "Gazing out across the moonscape, you realize that there are no words to properly describe it.  Vast... unwelcoming... those are just the start.  If you had to put it into one word, it would be this: lonely." The printed name of Moonscape is "moonscape".

Starry Sky is a backdrop. Starry Sky is in Lunar Surface. Understand "heaven" or "heavens" or "star" or "stars" as Starry Sky.  The description of Starry Sky is "The sky appears as a dark, enveloping blanket, studded with diamond-like stars which twinkle at you.  The two most prominent objects in the heavens are the Earth and the Sun." The printed name of Starry Sky is "starry sky".

The Sun is a backdrop. The Sun is in Lunar Surface. Understand "Sol" or "Helios" as Sun.  The description of the Sun is "The light emanating from the sun takes only minutes to travel this far.  It's a shame there's not more atmosphere to trap some of that heat and keep you warm.  Better watch what you wish for, though - the people of Earth asked for an atmosphere that could retain heat and we all know what happened there, don't we now?" The printed name of Starry Sky is "starry sky".

Outside Atlantean Base is a room.  Outside Atlantean Base is in Lunar Surface.  The description of Outside Atlantean Base is "You find yourself [if unvisited]lying on the ground outside the Atlantean Base.  You get up, dust yourself off, and begin to take in your surroundings.[otherwise]standing outside the Atlantean Base.[end if]  The silvery walls of the base rise tall into the starry sky, and seem to stretch on endlessly in either direction.  Behind you, to the south, lies a vast, unwelcoming expanse of moonscape.[if unvisited][paragraph break]You gaze up at the massive, silvery walls with a heavy heart - you don't see any way inside, at least not right off the bat.  Damn those Atlanteans and their treacherous ways.  They must have known you were coming, and built this giant wall just to thwart you!"  Instead of going south in Outside Atlantean Base, say "The moonscape draws on endlessly in that direction, desolate and barren.  Your destiny lies in front of you, inside the Atlantean Base."  Instead of going southeast in Outside Atlantean Base, say "The moonscape draws on endlessly in that direction, desolate and barren.  Your destiny lies in front of you, inside the Atlantean Base." Instead of going southwest in Outside Atlantean Base, say "The moonscape draws on endlessly in that direction, desolate and barren.  Your destiny lies in front of you, inside the Atlantean Base."  [Comment: I'll leave it to Mark to figure out how to get inside and what other responses the player might need here.]

The Silvery Walls are scenery in Outside Atlantean Base.  Understand "endless" or "massive" or "base" or "Atlantean base" or "base" as the Silvery Walls.  The description of the Silvery Walls are "A sprawling silvery mass, yes.  And filled, no doubt, with treachery.  You [italic type]must [roman type] find a way inside!"  Instead of taking the Silvery Walls, say "They are too massive, too endless, too... silvery to take."


Chapter 5.4 - The Ineffable Almanac

Instead of reading the Almanac:
	choose a random row in the Table of Ineffable Wisdom;
	say "Rather than start at the beginning of the Almanac, and having no curiosity in any specific entry in particular, you flip to a random page and begin reading at random:[paragraph break][response entry][paragraph break]Out of context, this may or may not make a whole lot of sense, but I suppose that's what you get for not looking up a specific entry."

Table of Ineffable Wisdom (continued)
topic	response
"marmot" or "marmots"	"Marmots are generally large, extremely adorable ground squirrels.  They are denizens of the mountainous regions of the world.  Despite their unassuming cuteness, some silly historians suggest that marmots, rather than rats, were the primary carriers of the Bubonic plague during several historic outbreaks.  But they are so wonderful and charming they couldn't possible have brought so much suffering into the world.  Most marmots are highly social, and use loud whistles to communicate with one another, especially when alarmed.  They are also very curious critters, and will happily try to unzip the zippers on unattended backpacks to see what's inside."
"fracture" or "fractures"	"Fracturing bones is usually quite painful and should generally be avoided as a matter of course.  Skeletal fractures can occur in an infinite number of ways, only a few of which are included here for the sake of brevity:[paragraph break]---> Getting lit and taking your lunar rover for a spin without due regard for the safety of yourself or others.[paragraph break]---> Getting lit, then challenging a boar grumptar to a wrestling match.[paragraph break]---> Getting lit and pretending you can fly over a lunar crater.[paragraph break]Please notice the common thread in all of these examples and remember the anti-binging slogan, kids: UNCHECKED DRINKING LEADS TO ABSENCE OF THINKING!  And [italic type]that's [roman type] one to grow on."
"skeleton" or "bone" or "bones" or "skellington" or "cartilage"	"The skeleton, sometimes colloquially referred to as the 'skellington,' is the hardened structure (bones and cartilage) that provides a frame for the body of an animal.  This structure may be provided externally or internally.  In either case, the frame is not indestructible and care should be taken not to damage it.  SEE ALSO: fractures"
"drink" or "drinking" or "binge" or "binging"	"Drinking is the act of consuming a liquid through the mouth. Sometimes, this is a good thing.  Water, for example, is required for many of life's physiological processes.  However, 'drinking' may also refer specifically to the ingestion of alcohol, something which is strictly forbidden (or at least greatly frowned upon) in the Cosmic Law."
"Cosmic Law" or "Law"	"Your notes on this are pretty simple: anything fun is generally against the Cosmic Law...[line break]...but then again, you're only guilty if you get caught."
"boar" or "grumptar"	"Not to be confused with your Aunt Bertha, grumptars are a very dangerous species indeed.  AFGNCAAPs which have wrestled with a boar grumptar and lived to tell the tale state that the only creature they fear more is the grue."
"AFGNCAAP" or "AFGNCAAPs"	"Ageless, Faceless, Gender Neutral, Culturally Ambiguous Adventure Person.  [bold type]DUH.[roman type]  Didn't you pay attention during IF Theory?  Or were you too busy dreaming about going into space?  Well, your day dreams certainly paid off, didn't they, slacker?"
"wombat" or "wombats"	"Deceptively adorable, these mythical creatures from the fictional continent of Australia are about a meter long, with a very short tail.  A favorite prey of the Tasmanian devil (also mythical), wombats are generally thought to be shy herbivores.  Legend holds, however, that they possess sharp teeth and claws, can run at 40 km/hr, and have been known to kill the (equally mythical) dingo.  They have even been known to exist in vinyards.  That is, if they're actually real, which they're not.  But if they [italic type]were [roman type] real, it would also be interesting to note that their scat is cubical."
"devil" or "Tasmanian devil" or "devils" or "Tasmanian devils"	"Tasmanian devils are mythical creatures from a made-up place called Tasmania, which is an island off of the (also fictional) continent of Australia.  They don't actually exist - just the sort of frightening stuff of scary bedtime stories, really - but legend tells of a small, dog-like marsupial known for its black fur, offensive odor when stressed, extremely loud and disturbing screech, and viciousness when feeding."
"dingo" or "dingos" or "dingoes" or "warrigal" or "warrigals"	"Dingoes come in two sorts: the real dingoes, which only exist in Southeast Asia, and the mythical dingoes that eat babies from the fictional continent of Australia.  In either case, they're a wild dog a bit smaller than your average North American wolf."
"wolf" or "wolves" or "North American wolf" or "North American wolves" or "American wolf" or "American wolves"	"Wolves are real, but generally not a danger to humans.  There are more important things to be afraid of... werewolves, for instance.  Or, if you're really into make-believe, dingoes."
"werewolf" or "werewolves" or "lycanthrope" or "wolfman" or "werefolk"	"The werefolk are a dangerous sort - a cursed people who change from man to beast and back again whenever there is a full moon.  It's difficult to say which werewolves have it worse - the werewolves of Earth, who must endure changing back and forth whenever there is a full moon, or the werewolves on the Moon, where the Moon is - let's face it - always full.  Speculation has it that werewolves also exist on other planets, but to date this has not been proven, and so no information is available, say, on Martian werewolves."
"wallaby" or "wallabies" or "wallabee" or "whallabee"	"Deceptively adorable, these mythical creatures from the fictional continent of Australia are smaller than their closely-related (though equally mythical) cousin, the kangaroo.  Seeing as how neither one exists, the dividing line between what constitutes a wallaby and what constitutes a kangaroo is somewhat arbitrary.  In general, a wallaby is smaller and stockier than a kangaroo, a kangaroo is generally larger and lankier than a wallaby, and a 'wallaroo' is what you call a specimen if you can't bring yourself to otherwise pigeon-hole the creature.  In myth, wallabies, kangaroos, and wallaroos live in a variety of habitats, and one can never be entirely certain that any given area is safe from their kicking feet and sharpened claws.  They have even been known to exist in vinyards."
"kangaroo" or "kangaroos"	"Deceptively adorable, these mythical creatures from the fictional continent of Australia are larger than their closely-related (though equally mythical) cousin, the wallaby.  Seeing as how neither one exists, the dividing line between what constitutes a kangaroo and what constitutes a wallaby is somewhat arbitrary.  In general, a kangaroo is generally larger and lankier than a wallaby, a wallaby is smaller and stockier than a kangaroo, and a 'wallaroo' is what you call a specimen if you can't bring yourself to otherwise pigeon-hole the creature.  In myth, kangaroos, wallabies, and wallaroos live in a variety of habitats, and one can never be entirely certain that any given area is safe from their kicking feet and sharpened claws.  They have even been known to exist in vinyards."
"wallaroo" or "wallaroos"	"Deceptively adorable, these mythical creatures are from the fictional continent of Australia.  In myth, kangaroos, wallabies, and wallaroos live in a variety of habitats, and one can never be entirely certain that any given area is safe from their kicking feet and sharpened claws.  They have even been known to exist in vinyards.  SEE ALSO: kangaroo.  SEE ALSO: wallaby."
"vinyard" or "vineyard"	"A vinyard can be a pleasant place in which to pass an afternoon, so long as there are no wallabies about.  Good thing wallabies don't actually exist."
"Aunt Bertha" or "Bertha" or "horrible"	"Aunt Bertha wasn't exactly your favorite aunt.  When you were forced to stay with her as a child, she told you horrible, terrible bedtime stories about small children being eviscerated by wallabies."
"mother" or "mom" or "mum" or "mama" or "mommy"	"Your mother was a beautiful, amazing woman, as far as you can remember.  Unfortunately, she was abducted by the Atlanteans when you were but a wee child, and you were sent to live with horrible Aunt Bertha."
"father" or "dad" or "papa" or "daddy"	"Your father was a rugged, handsome man, as far as you can remember.  Unfortunately, he was abducted by the Atlanteans when you were but a wee child, and you were sent to live with horrible Aunt Bertha."
[Table continuations encouraged.]

Part 6 - Entering the Unknown by "Mark J. Musante"

Whisper 6 is a scene. Whisper 6 begins when Whisper 5 ends. Whisper 6 ends when the player is in the Deep Interior Room for the first time.

Chapter 6.0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 6:
	move the player to Deep Interior Room;
	now every thing carried by the player is in Outside Atlantean Base;
	now the Almanac is in the player;
	rule succeeds.

test wh6 with "test wh6a / test wh6b"

test wh6a with "wear backpack / put all in backpack / x walls / ask leslie about walls / turn on flashlight / x walls /  touch twinkly / n / e / e / w / e / w / get box / tell leslie about box / tell leslie about boring corridor / open box / get button "

test wh6b with "attach calibrator to detangler / pull trigger / turn knob / push button "

Chapter 6.1 - Attempting to render the flashlight usable

After switching off the flashlight:
	remove the twinkly pattern from play; continue the action;
	
After switching on the flashlight:
	move the twinkly pattern to Outside Atlantean Base; continue the action;

Instead of attacking the Little Deceptively Adorable Snarling Wombat when the flashlight is switched on, say "You start to take a swing at it, but the bright light from the flashlight distracts you."

Chapter 6.2 - Dragging the Past into the Present

Table of Ineffable Wisdom (continued)
topic	response
"xyzzy"	"Although your Aunt Bertha used to use this word all the time (for example, when dropping a particularly large stone on her foot), you soon discovered that society in general tended to disapprove the use of this term."
"plugh"	"This word tends to trip off the tongue lightly, but you've never found a good situation in which to utter it."
"plover"	"Plovers are found throughout the world, and are characterised by relatively short bills. They hunt by sight, rather than by feel as longer-billed waders like snipe do."
"snipe"	"A Snipe is any of nearly 20 very similar wading bird species characterised by a very long slender bill and cryptic plumage. Snipe in the family Scolopacidae belong either to the small genera [italic type]Coenocorypha[roman type] (the New Zealand snipes) and [italic type]Lymnocryptes[roman type], or to the about 15 typical snipes in the genus [italic type]Gallinago[roman type]."
"vineyard"	"No vineyard would be complete without vines, and Lunar vineyards are no exception."
"silver" or "silvery" or "silver walls" or "silvery walls"	"Silver is a chemical element with the symbol Ag (Latin: [italic type]argentum[roman type]) and atomic number 47.  Atlanteans used silver for much of their building material, having learned how to make it stronger and more durable than any steel alloy created on Earth.  Showoffs."

[Table continuations encouraged.]

To meander about:
	say "There are no entrances visible east or west.  Trudging around the entire base on the off-chance that a convenient door might pop up borders on madness.  You'll have to try finding another way in."

Instead of going east in Outside Atlantean Base, meander about. Instead of going west in Outside Atlantean Base, meander about.

Understand "wall" as The Silvery Walls.  Instead of examining The Silvery Walls when the flashlight is switched on, say "What's this?  The light from the flashlight illuminates a twinkly pattern on the wall."

The twinkly pattern is scenery.  Instead of examining the twinkly pattern when the flashlight is switched on, say "The pattern sparkles and twinkles in the artificial light."  Instead of touching the twinkly pattern when the flashlight is switched on, meander inside.

To meander inside:
	say "You reach out for the pattern, and a spark of static shocks your finger.  You reach out again, and you are Drawn Inside.";
	now the player is in Plain Silver Room;

Chapter 6.3 - Inside the Atlantean Base on the Moon
	
Atlantean Base Interior is a region.

Plain Silver Room is a room.  Plain Silver Room is in Atlantean Base Interior.  The description of Plain Silver Room is "[fancy description]"

To say fancy description:
	say "The interior of the Atlantean's base is a great deal more hospitable than the lunar surface was.  But that's not saying much.  The walls of this room are as shiny and silvery as the giant silvery wall was outside. A simple, unmarked doorway leads north.";
	if the Plain Silver Room is unvisited begin;
		say "At last - you're on the brink of discovering what fate your parents met.  Perhaps they're even still alive!  Maybe they can reassure you that Aunt Bertha was your aunt by marriage and not by blood...";
		now every thing carried by the player is in Outside Atlantean Base;
		now the almanac is in the player; [This is too potentially useful to do without]
	end if;

Silvery corridor walls are a backdrop in Atlantean Base Interior.  Understand "wall" as silvery corridor walls.

Corridor Junction 27-B is north of Plain Silver Room.  Corridor Junction 27-B is in Atlantean Base Interior.  The description of Corridor Junction 27-B is "East and west sparkle and twinkle at you, down a long featureless corridor.  A doorway is in the south wall, with a Greek letter theta above."

Door 27-B is scenery in Corridor Junction 27-B. Understand "doorway" or "theta" or "greek" or "letter" as Door 27-B.  The description of Door 27-B is "Set into the silver wall above the dooryway is a theta symbol."

To say boring corridor:
	say "Silvery, sparkily, twinkly walls all tend to blend into your vision and make it all so very disorienting.  You're pretty sure the corridor leads east and west, but it's hard to be certain.[conditional paragraph break]"

BC1 is east of Corridor Junction 27-B.  The printed name of BC1 is "Boring Corridor".  Understand "Boring Corridor" as BC1.  The description of BC1 is "[boring corridor]".
BC2 is east of BC1.  The printed name of BC2 is "Boring Corridor".  The description of BC2 is "[boring corridor]".
BC3 is east of BC2.  The printed name of BC3 is "Boring Corridor".  The description of BC3 is "[boring corridor]".
BC4 is east of BC3.  The printed name of BC4 is "Boring Corridor".  The description of BC4 is "[boring corridor]".
BC5 is west of Corridor Junction 27-B.  The printed name of BC5 is "Boring Corridor".  The description of BC5 is "[boring corridor]".
BC6 is west of BC5.  The printed name of BC6 is "Boring Corridor".  The description of BC6 is "[boring corridor]".
BC7 is west of BC6.  The printed name of BC7 is "Boring Corridor".  The description of BC7 is "[boring corridor]".
BC8 is west of BC7.  The printed name of BC8 is "Boring Corridor".  The description of BC8 is "[boring corridor]".
BC8 is east of BC4.

BC1, BC2, BC3, BC4, BC5, BC6, BC7, and BC8 are in Atlantean Base Interior.

A small silver box is a container. "What's this?  A small yet silvery box?  This wasn't here before, was it?"  The description of the small silver box is "Smallish and silveryish.  [if the small silver box is closed]A fine seam runs round the outside indicating that it could be opened[otherwise]Inside the box you see [contents of the small silver box][end if]."  The small silver box is closed and openable.
A complicated button is inside the small silver box.  "A complicated mess of complication that results in a button just begging to be pushed."

After going to BC2 for the second time:
	now the small silver box is in BC1;
	continue the action.
	
Before pushing the complicated button when the complicated button is in the small silver box:
	say "It's too complicated to push it when it's inside the box.";
	stop the action;

Instead of pushing the complicated button:
	say "Ah, crap, not again.";
	now the player is in Deep Interior Room;
	remove the complicated button from play;
	remove the small silver box from play;
	now the almanac is in the player; [in case it was dropped or put into the box]
	
Deep Interior Room is a room.  "Even deeper still inside the Atlantean Base.  [if Deep Interior Room is unvisited]You're not sure any more if this means you're getting closer to finding your parents.[end if] Complex machinery hums deep within, and complex controls line every wall of this large, cavernous room.  The walls are still silvery, though.  There does not appear to be any exit."  Deep Interior Room is in Atlantean Base Interior.

Part 7 - Imposing some structure by Lucian Smith

Chapter 7.0 - Useful playtesting verbs - Not for release

Carry out skipping ahead during Whisper 7:
  Now the player is in Archive Lobby;
  Now the dial is not fixed in place;
  Now the dial is in the player;
  Now the crack in the wall is open;
  rule succeeds.

test wh7 with "x controls / look up controls in almanac / search controls for 14 / set dial to 14 / tell leslie about dial / tell leslie about deep interior room / z / attach analyzer to base / touch analyzer to me / tune calibrator / se ";

Chapter 1 - meta-scene objects

Nowhere At All is a room.  [Needed below so that 'nowhere' is a valid property for a room.]

Scene-manager is a thing.  It has a number called index.  The index of the scene-manager is 0.
The scene-manager has a thing called section item.  The section item of the scene-manager is nothing.
The scene-manager has a thing called old item.  The old item of the scene-manager is nothing.
The scene-manager has a thing called most recent item.  The most recent item of the scene-manager is nothing.
The scene-manager has a room called section place.  The section place of the scene-manager is nowhere.
The scene-manager has a room called old place.  The old place of the scene-manager is nowhere.
The scene-manager has a room called most recent place.  The most recent place of the scene-manager is nowhere.
The scene-manager has a number called counter.  The counter of the scene-manager is 0.


When Whisper 1 begins:  The meta-story advances in zero turns from now.
When Whisper 2 begins:  The meta-story advances in zero turns from now.
When Whisper 3 begins:  The meta-story advances in zero turns from now.
When Whisper 4 begins:  The meta-story advances in zero turns from now.
When Whisper 5 begins:  The meta-story advances in zero turns from now.
When Whisper 6 begins:  The meta-story advances in zero turns from now.
When Whisper 7 begins:  The meta-story advances in zero turns from now.
When Whisper 8 begins:  The meta-story advances in zero turns from now.
When Whisper 9 begins:  The meta-story advances in zero turns from now.
When Whisper 10 begins:  The meta-story advances in zero turns from now.

[At the time when the meta-story advances:  
  the scene-index pings in three turns from now;]
[We do this later, since we also need to do other stuff then that's not defined yet.]

At the time when the scene-index pings:  increase the index of the scene-manager by 1.

Wh1a is a scene. Wh1a begins when the index of the scene-manager is 1.
Wh1a ends when the index of the scene-manager is 2.
Wh2a is a scene.  Wh2a begins when Wh1a ends.  
Wh2a ends when the index of the scene-manager is 3.
Wh3a is a scene.  Wh3a begins when Wh2a ends.   
Wh3a ends when the index of the scene-manager is 4.
Wh4a is a scene.  Wh4a begins when Wh3a ends.   
Wh4a ends when the index of the scene-manager is 5.
Wh5a is a scene.  Wh5a begins when Wh4a ends.   
Wh5a ends when the index of the scene-manager is 6.
Wh6a is a scene.  Wh6a begins when Wh5a ends.  
Wh6a ends when the index of the scene-manager is 7.
Wh7a is a scene.  Wh7a begins when Wh6a ends.   
Wh7a ends when the index of the scene-manager is 8.
Wh8a is a scene.  Wh8a begins when Wh7a ends.   
Wh8a ends when the index of the scene-manager is 9.
Wh9a is a scene.  Wh9a begins when Wh8a ends.   
Wh9a ends when the index of the scene-manager is 10.
Wh10a is a scene.  Wh10a begins when Wh9a ends.   

Chapter 2 - Leslie and the first meta-scene

When wh1a begins:
  say "Your vision goes blurry for a second, and a voice seems to be speaking to you right out of your brain.[paragraph break]'Dave?  Dave?  Can you hear me?' says the voice.  'Hang on, we're trying to get you out of there.'";
  conversation part two in zero turns from now;
  Now the counter of the scene-manager is zero;

At the time when conversation part two:
  if examining and the noun is Leslie begin;
    conversation part two in zero turns from now;
  otherwise;
    say "The voice continues.  If you concentrate, you can just place the voice as Leslie's.  'Listen.  I think we can do this, but we need your help.  We need to calibrate on this end with something you've held on that end.  Can you describe something you've picked up, or something you're holding?  Try telling me about it.'";
  end if;
  Now the counter of the scene-manager is zero;

Every turn during wh1a:
 if the section item of the scene-manager is nothing begin;
    increase the counter of the scene-manager by one;
    if the counter of the scene-manager is greater than four begin;
      say "Leslie's voice resonates in your skull again.  'Dave?  I need you to tell me about something you've picked up.  I can't get you out without it.'";
      Now the counter of the scene-manager is zero;
    end if;
  otherwise if the section place of the scene-manager is nowhere;
    increase the counter of the scene-manager by one;
    if the counter of the scene-manager is greater than three begin;
      say "'I really need that room,' Leslie says again.  'We almost have a lock on your avatar.'";
      Now the counter of the scene-manager is zero;
    end if;
  end if;

After doing anything during wh1a:
  if the noun is leslie, now the counter of the scene-manager is zero;
  if the second noun is leslie, now the counter of the scene-manager is zero;
  continue the action;

Understand "Dave" as yourself.

Leslie is a woman.  She is scenery.  Understand "voice" as Leslie.  "You twist your head around, searching for the source of the voice.  'I'm not actually here, Dave.  You're stuck in some kind of simulation, and I'm communicating to you from the outside.  This is Leslie.  Do you remember?'"  Leslie can be annoyed.  Leslie is not annoyed.

After examining Leslie for the first time:  Now the description of Leslie is "Leslie is not actually here, but you've been hearing her voice inside your head."  The replies of Leslie is the Table of Leslie Replies.

[Instead of answering leslie that something, try asking lelie about topic understood.]

After deciding the scope of the player:  If the index of the scene-manager is greater than zero and the index of the scene-manager is less than 20, place Leslie in scope.

[Bugfix for scope bug introduced in 5G67:]
Procedural rule when the noun is leslie:
  Ignore the basic accessibility rule.

Procedural rule when the second noun is leslie:
  Ignore the basic accessibility rule.

Table of Leslie Replies
  topic	reply
  "me" or "myself" or "dave"	"'You were testing the simulation code when something went wrong.  Do you not even remember who you are any more?  That's bad.'"
  "her" or "leslie" or "herself"	"'I'm trying to get you out of there!  I think we can do this, just trust me.'"
  "simulation" or "simulator" or "code" or "wrong" or "what's wrong"	"'You were working on the simulator, but something went wrong and it started to interface with your brain directly.  Your own memories are now influencing the simulator in unpredictable ways, and the simulator is trying to keep up.  It's going to get weirder before it gets back to normal.'"
  "memory" or "memories"	"'Don't ask me, it's your brain!'"
  "Atlantis" or "atlantean" or "base" or "outside" or "walls" or "outside atlantean base" or "outside base" or "atlantean base"	"'I'm not sure about that.  My readout says something about walls?  And a flashlight?  It's not making much sense.'"
  "aunt" or "bertha"	"'Do you even [bold type]have[roman type] an Aunt Bertha?  Don't answer that, I don't want to know.  If she exists, I certainly can't tell you if she's your aunt by marriage or by blood.  I'm guessing she represents something in your psyche, or a desire you have.'"
  "parents" or "mom" or "dad"	"Leslie pauses.  'Dave, I know you took the death of your parents pretty hard.  Maybe that's why you're imagining trying to find them in some Atlantean base?' She sighs.  'That's not important right now.  We have to get you out of there, and get your normal memories restored.'"
  "machinery" or "controls" or "complex"	"'Well, let me see,' Leslie tells you, and you you hear her mumbling as she presumably looks at some readouts.  'Hmm.  All I can tell you is that you should have been given something with more information in it about that.  Sorry I can't be more help.'" 
[Feel free to add to this table if you want her to have information on your own section.  Hints, even, if you want.]

Instead of asking leslie about something when the topic understood is not a topic listed in the replies of the noun:
  say "Leslie either can't help you with that, or doesn't understand what you mean.".

Instead of answering Leslie that something when the topic understood is not a topic listed in the replies of the noun:
  say "Leslie either can't help you with that, or doesn't understand what you mean.".


A thing can be either noted or unnoted.  A thing is usually unnoted.
A thing can be either potential or bypassed.  A thing is usually potential.
A thing can be either observed or unobserved.  A thing is usually unobserved.

Every turn:
  repeat with stuff running through mentioned things begin;
    now the stuff is observed;
  end repeat;

A room can be either noted or unnoted.  A room is usually unnoted.
A room can be either potential or bypassed.  A room is usually potential.

At the time when the meta-story advances:  
  if the section item of the scene-manager is nothing or the section place of the scene-manager is nowhere begin;
  if the index of the scene-manager is greater than zero and the index of the scene-manager is less than 20 begin;
    now the index of the scene-manager is 20.
    say "'No, Dave, we're losing you!' Leslie cries.  'Don't...' and then her voice is cut off.";
    [LS Note:  Here is where we can put in a fix for sections with no new items, if need be.  But I don't have the energy for it right now, and don't want to have to fix a bug that won't exist.]
    repeat with lost running through detangler-kinds begin;
      if the lost is sticky begin;
        Now the lost is not sticky;
        remove the lost from play;
        say "[The lost] disappears!";
      end if;
    end repeat;
    stop the action;
  end if;
  end if;
  the scene-index pings in two turns from now;
  if the index of the scene-manager is greater than one begin;
    repeat with missed running through handled things begin;
      now the missed is bypassed;
    end repeat;
    repeat with skipped running through visited rooms begin;
      now the skipped is bypassed;
    end repeat;
    [Special rule for the first room in a section:]
    now the location is not bypassed;
  end if;
  we clear the scene-manager in one turn from now.

At the time when we clear the scene-manager:
  now the section item of the scene-manager is nothing;
  now the section place of the scene-manager is nowhere;

Understand the command "describe" as something new.  Understand "describe [something]" as examining.

Indicating to it about is an action applying to two things.  Understand "tell [someone] about [any handled thing]" as indicating to it about.  Understand "tell [someone] about [any visited room]" as indicating to it about.  Understand "tell [someone] about [any observed enterable thing]" as indicating to it about.  Understand "describe [any handled thing] to [someone]" as indicating to it about (with nouns reversed).  Understand "describe [any visited room] to [someone]" as indicating to it about (with nouns reversed).  Understand "describe [any observed enterable thing] to [someone]" as indicating to it about (with nouns reversed).

Does the player mean indicating to Leslie about something potential:  It is very likely.

Does the player mean indicating to Leslie about something unnoted:  It is likely.

Understand "show [any visited room] to [someone]" as indicating to it about (with nouns reversed).

Carry out indicating to it about:
  say "[The noun] is unimpressed."

Procedural rule when indicating to someone about something:
  ignore the can't reach inside rooms rule;
  ignore the can't reach inside closed containers rule;
  ignore the can't reach outside closed containers rule;

Procedural rule when indicating to someone about  a room:
  ignore the can't reach inside rooms rule;
  ignore the can't reach inside closed containers rule;
  ignore the can't reach outside closed containers rule;


Describing to it about is an action applying to two things.  Understand "tell [someone] about [any observed thing]" as describing to it about.

Carry out describing to it about:
  say "[The noun] is unimpressed."

Does the player mean describing to Leslie about something potential:  It is very likely.

Does the player mean describing to Leslie about something unnoted:  It is likely.

Procedural rule when describing to someone about something:
  ignore the can't reach inside rooms rule;
  ignore the can't reach inside closed containers rule;
  ignore the can't reach outside closed containers rule;

Instead of showing something to Leslie, try indicating to Leslie about the noun.

Instead of describing to Leslie about something, try indicating to Leslie about the second noun.

Instead of indicating to Leslie about something:
  If the second noun is noted begin;
    say "'Thanks, I got that already.'"  ;
    Stop the action;
  end if;
  Now the second noun is noted;
  if the second noun is bypassed begin;
    say "'OK, great, that... oh, drat.  You already grabbed that in the previous section, didn't you?  Sorry, I can't use it to get a lock on where you are any more.'";
    stop the action;
  end if;
  say "'Aha!  Got it!  Analyzing now...'[paragraph break]";
  if the section item of the scene-manager is nothing begin;
    now the section item of the scene-manager is the second noun;
    now the most recent item of the scene-manager is the second noun;
    Increase the score by 5;
    say "'Perfect!  OK, we've noted [the second noun] as characteristic of this section, which should help us get a bead on your location.";
    Advancement conversation in one turn from now;
  end if;

Instead of indicating to Leslie about a room:
  If the second noun is noted begin;
    say "'Thanks, but you told me about that room already.'";
    stop the action;
  end if;
  Now the second noun is noted;
  if the second noun is bypassed begin;
    say "'Dave, you already visited that room in the last section.  I need a new room for this section if I'm going to be able to lock on to your location properly.'";
    stop the action;
  end if;
  say "'Ah, perfect!  Analyzing [the second noun] now...'[paragraph break]";
  if the section place of the scene-manager is nowhere begin;
    now the section place of the scene-manager is the second noun;
    now the most recent place of the scene-manager is the second noun;
    Increase the score by 5;
    say "'Great, we have that room now.  That should help.  Re-calibrating...'";
    Advancement conversation in one turn from now;
  end if;

Instead of indicating to Leslie about something:
  if the second noun is noted begin;
    say "'Thanks, but you told me about that already.'";
    stop the action;
  end if;
  Now the second noun is noted;
  if the second noun is bypassed b